From b5ab283eeb1138e743831f3f04d29c04e58d9ecc Mon Sep 17 00:00:00 2001
From: D G Turner <digitall@scummvm.org>
Date: Sat, 26 Sep 2020 14:14:21 +0100
Subject: media-gfx/cura: Fix runtime crash at startup (4.6.1)

This needs to resolve the correct dependencies i.e. v4.6.1, not later
such as v4.7.0 as this will likely cause issues.

Signed-off-by: David G Turner <digitall@scummvm.org>
Signed-off-by: Sam James <sam@gentoo.org>
---
 media-gfx/cura/cura-4.6.1-r1.ebuild | 56 +++++++++++++++++++++++++++++++++++++
 media-gfx/cura/cura-4.6.1.ebuild    | 56 -------------------------------------
 2 files changed, 56 insertions(+), 56 deletions(-)
 create mode 100644 media-gfx/cura/cura-4.6.1-r1.ebuild
 delete mode 100644 media-gfx/cura/cura-4.6.1.ebuild

(limited to 'media-gfx/cura')

diff --git a/media-gfx/cura/cura-4.6.1-r1.ebuild b/media-gfx/cura/cura-4.6.1-r1.ebuild
new file mode 100644
index 000000000000..943f93053259
--- /dev/null
+++ b/media-gfx/cura/cura-4.6.1-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit cmake desktop python-single-r1 xdg
+
+MY_PN=Cura
+
+DESCRIPTION="A 3D model slicing application for 3D printing"
+HOMEPAGE="https://github.com/Ultimaker/Cura"
+SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+usb zeroconf"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="sys-devel/gettext"
+RDEPEND="${PYTHON_DEPS}
+	~dev-libs/libcharon-${PV}[${PYTHON_SINGLE_USEDEP}]
+	~dev-libs/libsavitar-${PV}:=[python,${PYTHON_SINGLE_USEDEP}]
+	~dev-python/uranium-${PV}[${PYTHON_SINGLE_USEDEP}]
+	~media-gfx/curaengine-${PV}
+	~media-gfx/fdm-materials-${PV}
+	$(python_gen_cond_dep '
+		dev-python/requests[${PYTHON_MULTI_USEDEP}]
+		dev-python/sentry-sdk[${PYTHON_MULTI_USEDEP}]
+		usb? ( dev-python/pyserial[${PYTHON_MULTI_USEDEP}] )
+		zeroconf? ( dev-python/zeroconf[${PYTHON_MULTI_USEDEP}] )
+	')"
+DEPEND="${RDEPEND}"
+
+DOCS=( README.md )
+PATCHES=( "${FILESDIR}/${PN}-4.6.1-fix-install-paths.patch" )
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_prepare() {
+	sed -i "s/set(CURA_VERSION \"master\"/set(CURA_VERSION \"${PV}\"/" CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPYTHON_SITE_PACKAGES_DIR="$(python_get_sitedir)"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doicon icons/*.png
+	python_optimize "${D}${get_libdir}"
+}
diff --git a/media-gfx/cura/cura-4.6.1.ebuild b/media-gfx/cura/cura-4.6.1.ebuild
deleted file mode 100644
index bbd5d0b29de1..000000000000
--- a/media-gfx/cura/cura-4.6.1.ebuild
+++ /dev/null
@@ -1,56 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{6,7,8} )
-inherit cmake desktop python-single-r1 xdg
-
-MY_PN=Cura
-
-DESCRIPTION="A 3D model slicing application for 3D printing"
-HOMEPAGE="https://github.com/Ultimaker/Cura"
-SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="LGPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
-IUSE="+usb zeroconf"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-BDEPEND="sys-devel/gettext"
-RDEPEND="${PYTHON_DEPS}
-	>=dev-libs/libcharon-${PV:0:3}[${PYTHON_SINGLE_USEDEP}]
-	>=dev-libs/libsavitar-${PV:0:3}:=[python,${PYTHON_SINGLE_USEDEP}]
-	>=dev-python/uranium-${PV:0:3}[${PYTHON_SINGLE_USEDEP}]
-	>=media-gfx/curaengine-${PV:0:3}
-	>=media-gfx/fdm-materials-${PV:0:3}
-	$(python_gen_cond_dep '
-		dev-python/requests[${PYTHON_MULTI_USEDEP}]
-		dev-python/sentry-sdk[${PYTHON_MULTI_USEDEP}]
-		usb? ( dev-python/pyserial[${PYTHON_MULTI_USEDEP}] )
-		zeroconf? ( dev-python/zeroconf[${PYTHON_MULTI_USEDEP}] )
-	')"
-DEPEND="${RDEPEND}"
-
-DOCS=( README.md )
-PATCHES=( "${FILESDIR}/${PN}-4.6.1-fix-install-paths.patch" )
-S="${WORKDIR}/${MY_PN}-${PV}"
-
-src_prepare() {
-	sed -i "s/set(CURA_VERSION \"master\"/set(CURA_VERSION \"${PV}\"/" CMakeLists.txt || die
-	cmake_src_prepare
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DPYTHON_SITE_PACKAGES_DIR="$(python_get_sitedir)"
-	)
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-	doicon icons/*.png
-	python_optimize "${D}${get_libdir}"
-}
-- 
cgit v1.2.3-65-gdbad