From b06b7c6ea7f8beda52923f8ea8bbd61c4438fe07 Mon Sep 17 00:00:00 2001
From: Chris Mayo <aklhfex@gmail.com>
Date: Fri, 2 Oct 2020 18:52:08 +0100
Subject: media-gfx/gnofract4d: version bump to 4.3_p20200821

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Chris Mayo <aklhfex@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/15987
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 .../gnofract4d/gnofract4d-4.3_p20200821.ebuild     | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 media-gfx/gnofract4d/gnofract4d-4.3_p20200821.ebuild

(limited to 'media-gfx/gnofract4d/gnofract4d-4.3_p20200821.ebuild')

diff --git a/media-gfx/gnofract4d/gnofract4d-4.3_p20200821.ebuild b/media-gfx/gnofract4d/gnofract4d-4.3_p20200821.ebuild
new file mode 100644
index 000000000000..5f9466e0023f
--- /dev/null
+++ b/media-gfx/gnofract4d/gnofract4d-4.3_p20200821.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 optfeature virtualx xdg
+
+COMMIT="47752e0d240d9f2686c2a69d813ac5112bda1ad3"
+
+DESCRIPTION="A program for drawing beautiful mathematically-based images known as fractals"
+HOMEPAGE="https://fract4d.github.io/gnofract4d/"
+SRC_URI="https://github.com/fract4d/gnofract4d/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	media-libs/libpng:0=
+	virtual/jpeg
+	test? (
+		media-video/ffmpeg[vpx,zlib]
+	)"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	x11-libs/gtk+:3[introspection]"
+BDEPEND="virtual/pkgconfig"
+
+distutils_enable_tests pytest
+
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+src_prepare() {
+	sed -i -e "s:share/doc/gnofract4d/:share/doc/${PF}/:" setup.py || die
+	# test_regress.py does not provide pytest with any tests and inspecting it requires dev-python/pillow
+	rm test_regress.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_compile_all() {
+	if use test; then
+		ln -s "${BUILD_DIR}"/lib/fract4d/*.so fract4d/ || die
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	optfeature "creating videos" media-video/ffmpeg[vpx,zlib]
+}
-- 
cgit v1.2.3-65-gdbad