From 21ca65c01c7a57a599cdb999cdd3612bffc579d5 Mon Sep 17 00:00:00 2001
From: Thomas Beierlein <tomjbe@gentoo.org>
Date: Sat, 19 Sep 2015 18:39:33 +0200
Subject: media-libs/hamlib: Major version bump

---
 media-libs/hamlib/Manifest          |  1 +
 media-libs/hamlib/hamlib-3.0.ebuild | 83 +++++++++++++++++++++++++++++++++++++
 2 files changed, 84 insertions(+)
 create mode 100644 media-libs/hamlib/hamlib-3.0.ebuild

(limited to 'media-libs/hamlib')

diff --git a/media-libs/hamlib/Manifest b/media-libs/hamlib/Manifest
index 17378b86778f..bf3a3c315513 100644
--- a/media-libs/hamlib/Manifest
+++ b/media-libs/hamlib/Manifest
@@ -1 +1,2 @@
 DIST hamlib-1.2.15.3.tar.gz 1675879 SHA256 a2ca4549e4fd99d6e5600e354ebcb57502611aa63c6921c1b8a825289833f75e SHA512 88f9cb8d82d813ac02944def0adf6eada0e4ed1407f60e344d51172462d51ab0c3ddd9cbf9ef8cbd61efba6c4158a77acb7c23b886e174c9a082bf1dd11f5baa WHIRLPOOL 33f8e114d05c778e30c1b634e2494cd3f9d89213ccc58b34b4d195bb4f1c803c5451f54c8e232bf276a1daebe6c0a01bae73a51fa90538fe537d3b5bf4ce91de
+DIST hamlib-3.0.tar.gz 2074188 SHA256 bc16546161a47e21a44a710a40aeb0bce478f112bffcc4f253eb27e150f1c21e SHA512 16ac66ab91d44c364054aa6ba8292a6538886744d83a83eb0887f55407f836e1d4a402cc7a41576594bea8100c2eefa26bae212f767a68b2a4db7a709166cbd2 WHIRLPOOL 31f96037260160e83f376e87f35669cac73772b73d4b50bf78b32893de17d36e02d41d71ab393ac6fa27efbb387a88d71bdc8cb4a7c02c7251b141afea6d82a9
diff --git a/media-libs/hamlib/hamlib-3.0.ebuild b/media-libs/hamlib/hamlib-3.0.ebuild
new file mode 100644
index 000000000000..ad9ec0a406a3
--- /dev/null
+++ b/media-libs/hamlib/hamlib-3.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools-utils eutils multilib python-single-r1
+
+DESCRIPTION="Ham radio backend rig control libraries"
+HOMEPAGE="http://sourceforge.net/apps/mediawiki/hamlib"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="doc perl python tcl"
+
+RESTRICT="test"
+
+RDEPEND="
+	=virtual/libusb-0*
+	dev-libs/libxml2
+	sys-libs/readline:0
+	perl? ( dev-lang/perl )
+	python? ( ${PYTHON_DEPS} )
+	tcl? ( dev-lang/tcl:0= )"
+
+DEPEND=" ${RDEPEND}
+	virtual/pkgconfig
+	dev-lang/swig
+	>=sys-devel/libtool-2.2
+	doc? ( app-doc/doxygen )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DOCS=(AUTHORS NEWS PLAN README README.betatester README.developer TODO)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# fix hardcoded libdir paths
+	sed -i -e "s#fix}/lib#fix}/$(get_libdir)/hamlib#" \
+		-e "s#fix}/include#fix}/include/hamlib#" \
+		hamlib.pc.in || die "sed failed"
+
+	# make building of documentation compatible with autotools-utils
+	sed -i -e "s/doc:/html:/g" doc/Makefile.am || die "sed failed"
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--libdir=/usr/$(get_libdir)/hamlib
+		--disable-static
+		--with-xml-support
+		$(use_with perl perl-binding)
+		$(use_with python python-binding)
+		$(use_with tcl tcl-binding)
+		--disable-silent-rules
+	)
+	autotools-utils_src_configure
+}
+
+src_compile() {
+	autotools-utils_src_compile
+	use doc && autotools-utils_src_compile html
+}
+
+src_install() {
+	use doc && HTML_DOCS=("${AUTOTOOLS_BUILD_DIR}/doc/html/")
+	autotools-utils_src_install
+
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins "${AUTOTOOLS_BUILD_DIR}"/hamlib.pc || die "doins failed"
+
+	echo "LDPATH=/usr/$(get_libdir)/hamlib" > "${T}"/73hamlib
+	doenvd "${T}"/73hamlib || die "doenvd failed"
+}
-- 
cgit v1.2.3-65-gdbad