From 6bf5b428988d090c2a62110c51de0054c9f657d0 Mon Sep 17 00:00:00 2001
From: Nick Sarnie <sarnex@gentoo.org>
Date: Wed, 16 Dec 2020 21:18:34 -0500
Subject: media-libs/vulkan-layers: Version bump and drop old

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Nick Sarnie <sarnex@gentoo.org>
---
 media-libs/vulkan-layers/Manifest                  |  1 +
 .../vulkan-layers/vulkan-layers-1.2.162.ebuild     | 53 ++++++++++++++++++++++
 media-libs/vulkan-layers/vulkan-layers-9999.ebuild |  2 +-
 3 files changed, 55 insertions(+), 1 deletion(-)
 create mode 100644 media-libs/vulkan-layers/vulkan-layers-1.2.162.ebuild

(limited to 'media-libs/vulkan-layers')

diff --git a/media-libs/vulkan-layers/Manifest b/media-libs/vulkan-layers/Manifest
index 9987d4a79a71..be460bd294ba 100644
--- a/media-libs/vulkan-layers/Manifest
+++ b/media-libs/vulkan-layers/Manifest
@@ -1 +1,2 @@
 DIST vulkan-layers-1.2.154.tar.gz 2312569 BLAKE2B 01415b6bb1a2b3e89569ac1a5010be12f752d1a6cb8885aa8ba2d062e5742313f75c8cb51c078b2020afcecffbbf8139a8a97220beae556191427bbcbc7a21e7 SHA512 44cdf3c72d6933969959ee959121de8e32a225bb941d9d7f3b2785bbae26d56cfdb0efb072c11649c316b5cef00b44f2f2415071c39faa0fe00a9e7c66098b7f
+DIST vulkan-layers-1.2.162.tar.gz 2398927 BLAKE2B febfcc88584cb7d69ac2f2bd95a73921d2dc92524b05f17e7d2a9f99336416260da60eefc560d93ad788d9a185d4dd865881f5bc8faf0dae388bacca59a21b7a SHA512 85eba0e1d07cafad212ef611fb1aef3113b6609361476cda7176a49110fe62d257b815f7c622d6ba959872785242e2231c7245242e7794ff5e60325d10f3061b
diff --git a/media-libs/vulkan-layers/vulkan-layers-1.2.162.ebuild b/media-libs/vulkan-layers/vulkan-layers-1.2.162.ebuild
new file mode 100644
index 000000000000..9cb8d0ae93b7
--- /dev/null
+++ b/media-libs/vulkan-layers/vulkan-layers-1.2.162.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=Vulkan-ValidationLayers
+CMAKE_ECLASS="cmake"
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}"/${MY_PN}-${PV}
+fi
+
+DESCRIPTION="Vulkan Validation Layers"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-ValidationLayers"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="wayland X"
+
+BDEPEND=">=dev-util/cmake-3.10.2"
+DEPEND="${PYTHON_DEPS}
+	>=dev-util/glslang-10.11.0.0_pre20201216:=[${MULTILIB_USEDEP}]
+	>=dev-util/spirv-tools-2020.6:=[${MULTILIB_USEDEP}]
+	>=dev-util/vulkan-headers-${PV}
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_LAYER_SUPPORT_FILES=ON
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DBUILD_TESTS=OFF
+		-DGLSLANG_INSTALL_DIR="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_INCLUDEDIR="${EPREFIX}/usr/include/vulkan/"
+		-DSPIRV_HEADERS_INSTALL_DIR="${EPREFIX}/usr/include/spirv"
+	)
+	cmake_src_configure
+}
diff --git a/media-libs/vulkan-layers/vulkan-layers-9999.ebuild b/media-libs/vulkan-layers/vulkan-layers-9999.ebuild
index b8f6fafe2d3d..4d2f9616d6ca 100644
--- a/media-libs/vulkan-layers/vulkan-layers-9999.ebuild
+++ b/media-libs/vulkan-layers/vulkan-layers-9999.ebuild
@@ -5,7 +5,7 @@ EAPI=7
 
 MY_PN=Vulkan-ValidationLayers
 CMAKE_ECLASS="cmake"
-PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_COMPAT=( python3_{6,7,8,9} )
 inherit cmake-multilib python-any-r1
 
 if [[ ${PV} == *9999* ]]; then
-- 
cgit v1.2.3-65-gdbad