From bae5cef1d5d1bd0ed3cb1512f813414c1b13ba8f Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Thu, 13 Dec 2018 11:17:12 +0100
Subject: media-sound/picard: 2.0.4 version bump

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 media-sound/picard/Manifest            |  1 +
 media-sound/picard/picard-2.0.4.ebuild | 77 ++++++++++++++++++++++++++++++++++
 media-sound/picard/picard-9999.ebuild  |  5 +--
 3 files changed, 80 insertions(+), 3 deletions(-)
 create mode 100644 media-sound/picard/picard-2.0.4.ebuild

(limited to 'media-sound/picard')

diff --git a/media-sound/picard/Manifest b/media-sound/picard/Manifest
index 56d3049fc4ea..fbc6a04f9777 100644
--- a/media-sound/picard/Manifest
+++ b/media-sound/picard/Manifest
@@ -1 +1,2 @@
 DIST picard-2.0.3.tar.gz 2748358 BLAKE2B ff71f9d7836b9f797a539db772e2ffcb8cb9ba4c25997c01590292bf1b7b5d311089174313af86f1eb0e82af48bc8f350578ae6bdffba3c6b3bf98b934481f8d SHA512 759252fa3c43af1bfc09d85ef90fe451e674bfebaee31838bd2779380d1b8ad817f899896baeccf583464566eb2acfe886c8288d1757faaaff2dc17c3b8ef6ae
+DIST picard-2.0.4.tar.gz 2759058 BLAKE2B e8a2a5aed7b8c99e31c1765906481432d310fd41fa01a611c7d82b182468cf4bfeb5a5aaab74c96c0971f21af3ba690537212c29c75433296cab6a1a409edf6d SHA512 cdc5f1ddeb84705fc792fb77a6d0ba06a5baf812799054ac0fd4959dfe788009f25b6f89ad0c28720f1c7c85af61534ca4f1e9e8efd6ec3cc78578d0f0b3ab32
diff --git a/media-sound/picard/picard-2.0.4.ebuild b/media-sound/picard/picard-2.0.4.ebuild
new file mode 100644
index 000000000000..760daf7633e6
--- /dev/null
+++ b/media-sound/picard/picard-2.0.4.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+DISTUTILS_SINGLE_IMPL=1
+DISABLE_AUTOFORMATTING=true
+inherit distutils-r1 gnome2-utils readme.gentoo-r1 xdg-utils
+
+DESCRIPTION="Cross-platform music tagger"
+HOMEPAGE="https://picard.musicbrainz.org"
+SRC_URI="https://musicbrainz.osuosl.org/pub/musicbrainz/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+
+RDEPEND="
+	dev-python/PyQt5[declarative,gui,network,widgets,${PYTHON_USEDEP}]
+	dev-qt/qtgui:5[accessibility]
+	>=media-libs/mutagen-1.38"
+DEPEND="
+	nls? ( dev-qt/linguist-tools:5 )
+"
+
+RESTRICT="test" # doesn't work with ebuilds
+
+S="${WORKDIR}/${PN}-release-${PV}"
+
+python_compile() {
+	local build_args=(
+		--disable-autoupdate
+	)
+	if ! use nls; then
+		build_args+=( --disable-locales )
+	fi
+	distutils-r1_python_compile ${build_args[@]}
+}
+
+python_install() {
+	local install_args=(
+		--disable-autoupdate
+		--skip-build
+	)
+	if ! use nls; then
+		install_args+=( --disable-locales )
+	fi
+	distutils-r1_python_install ${install_args[@]}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	local DOC_CONTENTS="Install optional package media-libs/chromaprint[tools] to enable
+calculation and lookup of AcoustID fingerprints.
+
+Install optional package dev-python/python-discid to enable
+calculation and lookup of compact disc identifiers (disc IDs).
+
+If you are upgrading Picard and it does not start, try removing
+Picard's settings:
+	rm ~/.config/MusicBrainz/Picard.conf"
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}
diff --git a/media-sound/picard/picard-9999.ebuild b/media-sound/picard/picard-9999.ebuild
index 89f14c4bd17f..e29c2cbc2b5c 100644
--- a/media-sound/picard/picard-9999.ebuild
+++ b/media-sound/picard/picard-9999.ebuild
@@ -1,12 +1,11 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
 
-PYTHON_COMPAT=( python3_{5,6} )
+PYTHON_COMPAT=( python3_{5,6,7} )
 DISTUTILS_SINGLE_IMPL=1
 DISABLE_AUTOFORMATTING=true
-
 EGIT_REPO_URI="https://github.com/metabrainz/picard"
 inherit distutils-r1 git-r3 gnome2-utils readme.gentoo-r1 xdg-utils
 
-- 
cgit v1.2.3-65-gdbad