From 20c0969abc918f14a74b0586556a1fb5f9181be7 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sat, 26 Sep 2020 14:20:27 +0200
Subject: media-video/ffmpeg2theora: Port to py3
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/735546
Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../ffmpeg2theora/ffmpeg2theora-0.30-r1.ebuild     | 55 ++++++++++++++++++++++
 .../ffmpeg2theora/ffmpeg2theora-0.30.ebuild        | 48 -------------------
 .../files/ffmpeg2theora-0.29-underlinking.patch    |  4 +-
 3 files changed, 57 insertions(+), 50 deletions(-)
 create mode 100644 media-video/ffmpeg2theora/ffmpeg2theora-0.30-r1.ebuild
 delete mode 100644 media-video/ffmpeg2theora/ffmpeg2theora-0.30.ebuild

(limited to 'media-video/ffmpeg2theora')

diff --git a/media-video/ffmpeg2theora/ffmpeg2theora-0.30-r1.ebuild b/media-video/ffmpeg2theora/ffmpeg2theora-0.30-r1.ebuild
new file mode 100644
index 000000000000..0e9cd2e06d01
--- /dev/null
+++ b/media-video/ffmpeg2theora/ffmpeg2theora-0.30-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+inherit python-any-r1 scons-utils toolchain-funcs
+
+DESCRIPTION="A simple converter to create Ogg Theora files"
+HOMEPAGE="http://www.v2v.cc/~j/ffmpeg2theora/"
+SRC_URI="http://www.v2v.cc/~j/${PN}/downloads/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="amd64 ~ppc ~ppc64 ~sparc x86"
+IUSE="kate"
+
+RDEPEND="
+	media-video/ffmpeg:0=[postproc]
+	>=media-libs/libvorbis-1.1
+	>=media-libs/libogg-1.1
+	>=media-libs/libtheora-1.1[encode]
+	kate? ( >=media-libs/libkate-0.3.7 )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.29-swr.patch
+	"${FILESDIR}"/${PN}-0.29-underlinking.patch
+)
+
+src_prepare() {
+	default
+	2to3 -n -w --no-diffs SConstruct || die
+}
+
+src_configure() {
+	SCONSARGS=(
+		APPEND_CCFLAGS="${CFLAGS}"
+		APPEND_LINKFLAGS="${LDFLAGS}"
+		prefix=/usr
+		mandir=PREFIX/share/man
+		libkate=$(usex kate 1 0)
+	)
+}
+
+src_compile() {
+	escons "${SCONSARGS[@]}"
+}
+
+src_install() {
+	escons "${SCONSARGS[@]}" destdir="${D}" install
+	dodoc AUTHORS ChangeLog README subtitles.txt TODO
+}
diff --git a/media-video/ffmpeg2theora/ffmpeg2theora-0.30.ebuild b/media-video/ffmpeg2theora/ffmpeg2theora-0.30.ebuild
deleted file mode 100644
index 49c6e4674e0a..000000000000
--- a/media-video/ffmpeg2theora/ffmpeg2theora-0.30.ebuild
+++ /dev/null
@@ -1,48 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-inherit eutils toolchain-funcs scons-utils
-
-DESCRIPTION="A simple converter to create Ogg Theora files"
-HOMEPAGE="http://www.v2v.cc/~j/ffmpeg2theora/"
-SRC_URI="http://www.v2v.cc/~j/${PN}/downloads/${P}.tar.bz2"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="amd64 ~ppc ~ppc64 ~sparc x86"
-IUSE="kate"
-
-RDEPEND="
-	media-video/ffmpeg:0=[postproc]
-	>=media-libs/libvorbis-1.1
-	>=media-libs/libogg-1.1
-	>=media-libs/libtheora-1.1[encode]
-	kate? ( >=media-libs/libkate-0.3.7 )"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
-
-src_prepare() {
-	epatch \
-		"${FILESDIR}"/${PN}-0.29-swr.patch \
-		"${FILESDIR}"/${PN}-0.29-underlinking.patch
-}
-
-src_configure() {
-	myesconsargs=(
-		APPEND_CCFLAGS="${CFLAGS}"
-		APPEND_LINKFLAGS="${LDFLAGS}"
-		prefix=/usr
-		mandir=PREFIX/share/man
-		libkate=$(usex kate 1 0)
-		)
-}
-
-src_compile() {
-	escons
-}
-
-src_install() {
-	escons destdir="${D}" install
-	dodoc AUTHORS ChangeLog README subtitles.txt TODO
-}
diff --git a/media-video/ffmpeg2theora/files/ffmpeg2theora-0.29-underlinking.patch b/media-video/ffmpeg2theora/files/ffmpeg2theora-0.29-underlinking.patch
index dc877603913a..791e39d87744 100644
--- a/media-video/ffmpeg2theora/files/ffmpeg2theora-0.29-underlinking.patch
+++ b/media-video/ffmpeg2theora/files/ffmpeg2theora-0.29-underlinking.patch
@@ -6,8 +6,8 @@ v = pow(v, g) * 255.0;    // mplayer's vf_eq2.c multiplies with 256 here, strang
 
 For build failure and log, see Gentoo bug #504698
 
---- SConstruct
-+++ SConstruct
+--- a/SConstruct
++++ b/SConstruct
 @@ -206,9 +206,8 @@
    if env['crossmingw']:
        env.Append(CCFLAGS=['-Wl,-subsystem,windows'])
-- 
cgit v1.2.3-65-gdbad