From ebbc52e34fa1c2f702c06154bad8540bfcfeefe4 Mon Sep 17 00:00:00 2001
From: Jakov Smolic <jakov.smolic@sartura.hr>
Date: Thu, 25 Feb 2021 19:01:52 +0100
Subject: net-im/err: Bump to 6.1.7

Closes: https://bugs.gentoo.org/751865
Closes: https://bugs.gentoo.org/754663
Signed-off-by: Jakov Smolic <jakov.smolic@sartura.hr>
Signed-off-by: Sam James <sam@gentoo.org>
---
 net-im/err/Manifest         |  1 +
 net-im/err/err-6.1.7.ebuild | 94 +++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+)
 create mode 100644 net-im/err/err-6.1.7.ebuild

(limited to 'net-im/err')

diff --git a/net-im/err/Manifest b/net-im/err/Manifest
index 3b52fdf76ff9..9b09a0caeaae 100644
--- a/net-im/err/Manifest
+++ b/net-im/err/Manifest
@@ -1 +1,2 @@
+DIST err-6.1.7.tar.gz 1359383 BLAKE2B 400bbf4a4180f74993a4414dc55f07a69b34b04277fecd073bd860df9dcd5da4873949df766c0c2f6b7a43b4e87153d0aa77b0abaf95bf9702d76c3c7b290abe SHA512 cd0dadc5ff380c71631bae7711bdba7345046fbe14e369c8efa8eed98752b9ea03f6e4fa3171df257a9d76686c610e28fac5f39f7e8e107348a5746e4354694b
 DIST errbot-6.1.4.tar.gz 207370 BLAKE2B 187e87cc36393f85c1405a29d332d703cdd2ac9d9c6b50178ff7382bc5feb620b69a77dc21ce8144fc24045f11067865c7273118fc25ec1ad9afb93d6ccc635e SHA512 60cc8f070e2420e4ef5f0124eb6d03b3cf01c44e148ebb8b92f5b504eb6968c754fd82771da9528daab62c9e9f4d6ef97ab1063f1093163208521b26e36b2f2d
diff --git a/net-im/err/err-6.1.7.ebuild b/net-im/err/err-6.1.7.ebuild
new file mode 100644
index 000000000000..981a4a81c279
--- /dev/null
+++ b/net-im/err/err-6.1.7.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+MY_PN="errbot"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Multiprotocol chatbot designed to be easily deployable and maintainable"
+HOMEPAGE="https://errbot.readthedocs.io/en/latest/"
+SRC_URI="https://github.com/errbotio/errbot/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+KEYWORDS="~amd64"
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="irc +xmpp"
+
+DEPEND="
+	acct-group/err
+	acct-user/err"
+RDEPEND="${DEPEND}
+	dev-python/ansi[${PYTHON_USEDEP}]
+	dev-python/bottle[${PYTHON_USEDEP}]
+	dev-python/colorlog[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/daemonize[${PYTHON_USEDEP}]
+	dev-python/deepmerge[${PYTHON_USEDEP}]
+	dev-python/dulwich[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/markdown[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/pyopenssl[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/webtest[${PYTHON_USEDEP}]
+	irc? (
+		dev-python/irc[${PYTHON_USEDEP}]
+	)
+	xmpp? (
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		dev-python/pyasn1-modules[${PYTHON_USEDEP}]
+		dev-python/slixmpp[${PYTHON_USEDEP}]
+	)
+"
+S="${WORKDIR}/${MY_P}"
+
+distutils_enable_tests pytest
+
+# NOTES:
+# 1. Support for BOT_SENTRY option is missing, cause
+#    we do not have apropriate packages in portage yet
+# 2. Currently only XMPP is supported(IRC still untested)
+# 3. Internal web server is temporarily removed (rocket-err from requires.txt)
+# 4. pygments-markdown-lexer dependency(needed only for debugging?) is temporarily removed (pygments-markdown-lexer from requires.txt)
+
+python_prepare_all() {
+	sed -i -e '/pygments-markdown-lexer/d' setup.py || die
+
+	# NameError: name 'slack' is not defined
+	rm tests/backend_tests/slack_test.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local deselect=(
+		--deselect tests/commands_test.py::test_plugin_cycle
+		--deselect tests/commands_test.py::test_broken_plugin
+		--deselect tests/commands_test.py::test_backup
+		--deselect tests/plugin_management_test.py::test_check_dependencies_requi
+	)
+
+	pytest -vv "${deselect[@]}" || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newinitd "${FILESDIR}"/errd.initd.2 errd
+	newconfd "${FILESDIR}"/errd.confd errd
+
+	dodir /etc/${PN}
+	keepdir /var/lib/${PN}
+	keepdir /var/log/${PN}
+	fowners -R err:err /var/lib/${PN}
+	fowners -R err:err /var/log/${PN}
+
+	insinto /etc/${PN}
+	newins errbot/config-template.py config.py
+}
-- 
cgit v1.2.3-65-gdbad