From 56bd759df1d0c750a065b8c845e93d5dfa6b549d Mon Sep 17 00:00:00 2001
From: "Robin H. Johnson" <robbat2@gentoo.org>
Date: Sat, 8 Aug 2015 13:49:04 -0700
Subject: proj/gentoo: Initial commit
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
---
 net-mail/libpst/libpst-0.6.60.ebuild | 63 ++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 net-mail/libpst/libpst-0.6.60.ebuild

(limited to 'net-mail/libpst/libpst-0.6.60.ebuild')

diff --git a/net-mail/libpst/libpst-0.6.60.ebuild b/net-mail/libpst/libpst-0.6.60.ebuild
new file mode 100644
index 000000000000..79a4353c0ed4
--- /dev/null
+++ b/net-mail/libpst/libpst-0.6.60.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+PYTHON_DEPEND="python? 2"
+
+inherit autotools eutils python
+
+DESCRIPTION="Tools and library for reading Outlook files (.pst format)"
+HOMEPAGE="http://www.five-ten-sg.com/libpst/"
+SRC_URI="http://www.five-ten-sg.com/${PN}/packages/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug dii doc python static-libs"
+
+RDEPEND="dii? ( media-gfx/imagemagick[png] )
+	gnome-extra/libgsf"
+DEPEND="${RDEPEND}
+	virtual/libiconv
+	virtual/pkgconfig
+	dii? ( media-libs/gd[png] )
+	python? ( >=dev-libs/boost-1.48[python] )"
+
+pkg_setup() {
+	if use python; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	# don't build the static python library
+	epatch "${FILESDIR}"/${PN}-0.6.52-no-static-python-lib.patch
+
+	# fix pkgconfig file for static linking
+	epatch "${FILESDIR}"/${PN}-0.6.53-pkgconfig-static.patch
+
+	# conditionally install the extra documentation
+	use doc || { sed -i -e "/SUBDIRS/s: html::" Makefile.am || die; }
+
+	# don't install duplicate docs
+	sed -i -e "/^html_DATA =/d" Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-libpst-shared \
+		$(use_enable debug pst-debug) \
+		$(use_enable dii) \
+		$(use_enable python) \
+		$(use_enable static-libs static) \
+		$(use python && echo --with-boost-python=boost_python-${PYTHON_ABI})
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}
-- 
cgit v1.2.3-65-gdbad