From c449a6de62497a9cf973b451ca278f0623f7d24d Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Sat, 21 Oct 2017 15:55:03 +0200
Subject: net-misc/usbip: Version bump (bug #634996 by Tomoatsu Shimada).

Package-Manager: Portage-2.3.12, Repoman-2.3.3
---
 net-misc/usbip/usbip-4.13.ebuild | 59 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 net-misc/usbip/usbip-4.13.ebuild

(limited to 'net-misc/usbip/usbip-4.13.ebuild')

diff --git a/net-misc/usbip/usbip-4.13.ebuild b/net-misc/usbip/usbip-4.13.ebuild
new file mode 100644
index 000000000000..93bbe26b7c77
--- /dev/null
+++ b/net-misc/usbip/usbip-4.13.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+ETYPE="sources"
+K_NOUSENAME=1
+inherit autotools eutils kernel-2
+
+DESCRIPTION="Userspace utilities for a general USB device sharing system over IP networks"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI="${KERNEL_URI}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="static-libs tcpd"
+RESTRICT=""
+
+RDEPEND=">=dev-libs/glib-2.6
+	sys-apps/hwids
+	>=sys-kernel/linux-headers-3.17
+	virtual/libudev
+	tcpd? ( sys-apps/tcp-wrappers )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS="AUTHORS README"
+
+S=${WORKDIR}/linux-${PV}/tools/usb/${PN}
+
+src_unpack() {
+	tar xJf "${DISTDIR}"/${A} linux-${PV}/tools/usb/${PN} || die
+}
+
+src_prepare() {
+	# remove -Werror from build, bug #545398
+	sed -i 's/-Werror[^ ]* //g' configure.ac || die
+
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use tcpd || echo --without-tcp-wrappers) \
+		--with-usbids-dir=/usr/share/misc
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}
+
+pkg_postinst() {
+	elog "For using USB/IP you need to enable USBIP_VHCI_HCD in the client"
+	elog "machine's kernel config and USBIP_HOST on the server."
+}
-- 
cgit v1.2.3-65-gdbad