From d65d2755d5c5abb31a846991847046f71748cb9e Mon Sep 17 00:00:00 2001
From: Michael Vetter <jubalh@iodoru.org>
Date: Wed, 14 Feb 2018 14:43:05 +0000
Subject: net-nntp/suck: Add version 4.3.3

Closes: https://bugs.gentoo.org/232581
Closes: https://bugs.gentoo.org/622880
Package-Manager: Portage-2.3.19, Repoman-2.3.6
Closes: https://github.com/gentoo/gentoo/pull/7185
---
 net-nntp/suck/suck-4.3.3.ebuild | 61 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 net-nntp/suck/suck-4.3.3.ebuild

(limited to 'net-nntp/suck/suck-4.3.3.ebuild')

diff --git a/net-nntp/suck/suck-4.3.3.ebuild b/net-nntp/suck/suck-4.3.3.ebuild
new file mode 100644
index 000000000000..684bae61e05e
--- /dev/null
+++ b/net-nntp/suck/suck-4.3.3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools
+
+DESCRIPTION="Grab news from a remote NNTP server and feed them to another"
+HOMEPAGE="https://lazarus-pkgs.github.io/lazarus-pkgs/suck.html"
+SRC_URI="https://github.com/lazarus-pkgs/suck/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="perl ssl"
+
+COMMON_DEPEND="sys-libs/gdbm:=
+	ssl? ( dev-libs/openssl:0= )"
+
+DEPEND="${COMMON_DEPEND}
+	sys-libs/db
+	perl? ( dev-lang/perl )"
+
+RDEPEND="${COMMON_DEPEND}
+	net-nntp/inn"
+
+PATCHES=( "${FILESDIR}/${PV}-fputs.patch" )
+
+src_prepare() {
+	default
+
+	# Fix paths to the locations in Gentoo
+	sed -i \
+		-e 's:/usr/bin/rnews:/usr/$(get_libdir)/news/bin/rnews:' \
+		-e 's:/var/lib/news/history:/var/spool/news/db/history:' \
+		suck_config.h || die "path adaption sed failed"
+
+	eautoreconf
+}
+
+src_configure() {
+	use ssl || sed -i -e 's/^SSL_/#SSL_/' Makefile.in || die "ssl sed failed"
+	use perl || sed -i -e 's/^PERL_/#PERL_/' Makefile.in || die "perl sed failed"
+
+	econf
+}
+
+src_compile() {
+	emake phrases.h
+	emake all lpost
+}
+
+src_install() {
+	dobin lmove lpost rpost suck testhost
+	doman man/*
+	dodoc CHANGELOG CONTENTS README*
+	docinto java
+	dodoc java/*
+	docinto perl
+	dodoc perl/*
+	docinto sample
+	dodoc sample/*
+}
-- 
cgit v1.2.3-65-gdbad