From bb0ee0073efe96e5bf0ae44507c5add30550c891 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sun, 27 Sep 2020 06:31:37 +0200
Subject: net-voip/telepathy-salut: Port to py3
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/735436
Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 net-voip/telepathy-salut/Manifest                  |  1 +
 .../telepathy-salut-0.8.1-r2.ebuild                | 77 ----------------------
 .../telepathy-salut-0.8.1-r3.ebuild                | 72 ++++++++++++++++++++
 3 files changed, 73 insertions(+), 77 deletions(-)
 delete mode 100644 net-voip/telepathy-salut/telepathy-salut-0.8.1-r2.ebuild
 create mode 100644 net-voip/telepathy-salut/telepathy-salut-0.8.1-r3.ebuild

(limited to 'net-voip')

diff --git a/net-voip/telepathy-salut/Manifest b/net-voip/telepathy-salut/Manifest
index 377336256ee7..805603224856 100644
--- a/net-voip/telepathy-salut/Manifest
+++ b/net-voip/telepathy-salut/Manifest
@@ -1 +1,2 @@
+DIST telepathy-salut-0.8.1-python3.patch 5878 BLAKE2B db76eaf004418d48359c0ca710a59782fc1cda304825c75259daca41f3cd94ced207be06db7e5fd4d290b8021276077076eed330c20c2249b1577f0670697f93 SHA512 b924fae314d9efcc22226415e5904521593821996cdef9e5149ebc5ee2ceb4c2c210c311aeed3a01e634cb6ddc8f36b83d1473d700a8a6d1171c934217ef4185
 DIST telepathy-salut-0.8.1.tar.gz 1823482 BLAKE2B 22f93d48cc749ed74ac1ee4103ea0bf5b1f93b2d14c95a4bd2edde977a5c43db5d5fe54dd246c561ee94f13b4030ab42c011f537a0e6688e8be3ac0aa0f1ca67 SHA512 34537ac9ce0b78015e184963ea79beaa7332ac11803f9683ff34577d9f0a14f7ed287aacb2c00059f2ff2f300c325a09a78a320e83d0a0031ad976da2c197a90
diff --git a/net-voip/telepathy-salut/telepathy-salut-0.8.1-r2.ebuild b/net-voip/telepathy-salut/telepathy-salut-0.8.1-r2.ebuild
deleted file mode 100644
index 910016e3338c..000000000000
--- a/net-voip/telepathy-salut/telepathy-salut-0.8.1-r2.ebuild
+++ /dev/null
@@ -1,77 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PYTHON_COMPAT=( python2_7 )
-inherit python-any-r1
-
-DESCRIPTION="A link-local XMPP connection manager for Telepathy"
-HOMEPAGE="https://telepathy.freedesktop.org/"
-SRC_URI="https://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ppc ~ppc64 sparc x86 ~x86-linux"
-IUSE="gnutls test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=dev-libs/dbus-glib-0.61
-	dev-libs/libxml2
-	>=dev-libs/glib-2.28:2
-	>=sys-apps/dbus-1.1.0
-	>=net-libs/telepathy-glib-0.17.1
-	>=net-dns/avahi-0.6.22[dbus]
-	net-libs/libsoup:2.4
-	sys-apps/util-linux
-	dev-db/sqlite:3
-	gnutls? ( >=net-libs/gnutls-2.10.2 )
-	!gnutls? ( >=dev-libs/openssl-0.9.8g:0[-bindist] )
-"
-DEPEND="${RDEPEND}
-	${PYTHON_DEPS}
-	dev-libs/libxslt
-	virtual/pkgconfig
-	test? (
-		>=dev-libs/check-0.9.4
-		net-libs/libgsasl
-		$(python_gen_any_dep 'dev-python/twisted[${PYTHON_USEDEP}]')
-	)
-"
-# FIXME: needs xmppstream python module
-#               >=net-dns/avahi-0.6.22[python]
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.5.0-uninitialized.patch # upstream bug #37701
-	"${FILESDIR}"/${P}-openssl-1.1.patch # bug #663994
-)
-
-python_check_deps() {
-	if use test ; then
-		 has_version "dev-python/twisted[${PYTHON_USEDEP}]"
-	fi
-}
-
-pkg_setup() {
-	python-any-r1_pkg_setup
-}
-
-src_configure() {
-	econf \
-		--disable-coding-style-checks \
-		--disable-plugins \
-		--disable-Werror \
-		--disable-static \
-		--disable-avahi-tests \
-		--with-tls=$(usex gnutls gnutls openssl)
-		#$(use_enable test avahi-tests)
-
-	# false positives according to bug #413581:
-	# unrecognized options: --disable-plugins, --disable-avahi-tests
-}
-
-src_install() {
-	MAKEOPTS+=" -j1" default # bug 413581
-	find "${D}" -name '*.la' -delete || die
-}
diff --git a/net-voip/telepathy-salut/telepathy-salut-0.8.1-r3.ebuild b/net-voip/telepathy-salut/telepathy-salut-0.8.1-r3.ebuild
new file mode 100644
index 000000000000..11d873b5e9a7
--- /dev/null
+++ b/net-voip/telepathy-salut/telepathy-salut-0.8.1-r3.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+inherit python-any-r1
+
+DESCRIPTION="A link-local XMPP connection manager for Telepathy"
+HOMEPAGE="https://telepathy.freedesktop.org/"
+SRC_URI="https://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz
+	https://src.fedoraproject.org/rpms/telepathy-salut/raw/master/f/${P}-python3.patch"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ppc ~ppc64 sparc x86 ~x86-linux"
+IUSE="gnutls test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/dbus-glib-0.61
+	dev-libs/libxml2
+	>=dev-libs/glib-2.28:2
+	>=sys-apps/dbus-1.1.0
+	>=net-libs/telepathy-glib-0.17.1
+	>=net-dns/avahi-0.6.22[dbus]
+	net-libs/libsoup:2.4
+	sys-apps/util-linux
+	dev-db/sqlite:3
+	gnutls? ( >=net-libs/gnutls-2.10.2 )
+	!gnutls? ( >=dev-libs/openssl-0.9.8g:0[-bindist] )
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	dev-libs/libxslt
+	virtual/pkgconfig
+	test? (
+		>=dev-libs/check-0.9.4
+		net-libs/libgsasl
+	)
+"
+# FIXME: needs xmppstream python module
+#               >=net-dns/avahi-0.6.22[python]
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.5.0-uninitialized.patch # upstream bug #37701
+	"${FILESDIR}"/${P}-openssl-1.1.patch # bug #663994
+	"${DISTDIR}"/${P}-python3.patch
+)
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	econf \
+		--disable-coding-style-checks \
+		--disable-plugins \
+		--disable-Werror \
+		--disable-static \
+		--disable-avahi-tests \
+		--with-tls=$(usex gnutls gnutls openssl)
+		#$(use_enable test avahi-tests)
+
+	# false positives according to bug #413581:
+	# unrecognized options: --disable-plugins, --disable-avahi-tests
+}
+
+src_install() {
+	MAKEOPTS+=" -j1" default # bug 413581
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad