From 1aac1736236bb22fb135f1154a4fa250a8bbe05a Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Wed, 8 Mar 2017 22:35:40 +0100
Subject: sci-biology/clustalw-mpi: Modernise to EAPI 6

Package-Manager: Portage-2.3.4, Repoman-2.3.2
Closes: https://github.com/gentoo/gentoo/pull/4165
---
 .../clustalw-mpi/clustalw-mpi-0.13-r1.ebuild       | 35 -------------------
 .../clustalw-mpi/clustalw-mpi-0.13-r2.ebuild       | 39 ++++++++++++++++++++++
 2 files changed, 39 insertions(+), 35 deletions(-)
 delete mode 100644 sci-biology/clustalw-mpi/clustalw-mpi-0.13-r1.ebuild
 create mode 100644 sci-biology/clustalw-mpi/clustalw-mpi-0.13-r2.ebuild

(limited to 'sci-biology/clustalw-mpi')

diff --git a/sci-biology/clustalw-mpi/clustalw-mpi-0.13-r1.ebuild b/sci-biology/clustalw-mpi/clustalw-mpi-0.13-r1.ebuild
deleted file mode 100644
index 7d68b61be5e3..000000000000
--- a/sci-biology/clustalw-mpi/clustalw-mpi-0.13-r1.ebuild
+++ /dev/null
@@ -1,35 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=4
-
-inherit eutils toolchain-funcs
-
-DESCRIPTION="An MPI implemention of the ClustalW general purpose multiple alignment algorithm"
-HOMEPAGE="http://www.bii.a-star.edu.sg/achievements/applications/clustalw/index.php"
-SRC_URI="http://web.bii.a-star.edu.sg/~kuobin/${PN}/${P}.tar.gz"
-
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-LICENSE="public-domain"
-IUSE="mpi_njtree static_pairalign"
-
-DEPEND="virtual/mpi"
-RDEPEND="${DEPEND}"
-
-src_prepare() {
-	epatch "${FILESDIR}"/${PV}-gentoo.patch
-	if use mpi_njtree; then
-		sed -e "s/TREES_FLAG/#TREES_FLAG/" -i Makefile || \
-			die "Failed to configure MPI code for NJ trees."
-	fi
-	if use static_pairalign; then
-		sed -e "s/DDYNAMIC_SCHEDULING/DSTATIC_SCHEDULING/" -i Makefile || \
-			die "Failed to configure static scheduling for pair alignments."
-	fi
-}
-
-src_install() {
-	dobin ${PN}
-	newdoc README.${PN} README
-}
diff --git a/sci-biology/clustalw-mpi/clustalw-mpi-0.13-r2.ebuild b/sci-biology/clustalw-mpi/clustalw-mpi-0.13-r2.ebuild
new file mode 100644
index 000000000000..76d3b80cde32
--- /dev/null
+++ b/sci-biology/clustalw-mpi/clustalw-mpi-0.13-r2.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="An MPI implemention of the ClustalW general purpose multiple alignment algorithm"
+HOMEPAGE="http://www.bii.a-star.edu.sg/achievements/applications/clustalw/index.php"
+SRC_URI="http://web.bii.a-star.edu.sg/~kuobin/${PN}/${P}.tar.gz"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="mpi_njtree static_pairalign"
+
+DEPEND="virtual/mpi"
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}"/${PV}-gentoo.patch )
+
+src_prepare() {
+	default
+
+	if use mpi_njtree; then
+		sed -e "s/TREES_FLAG/#TREES_FLAG/" -i Makefile || \
+			die "Failed to configure MPI code for NJ trees"
+	fi
+
+	if use static_pairalign; then
+		sed -e "s/DDYNAMIC_SCHEDULING/DSTATIC_SCHEDULING/" -i Makefile || \
+			die "Failed to configure static scheduling for pair alignments"
+	fi
+}
+
+src_install() {
+	dobin ${PN}
+	newdoc README.${PN} README
+}
-- 
cgit v1.2.3-65-gdbad