From df200939d611407fe7929826ce7e42a199b19161 Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Tue, 1 Jan 2019 16:35:11 +0100
Subject: x11-misc/nitrogen: Update HOMEPAGE/SRC_URI

Package-Manager: Portage-2.3.53, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---
 x11-misc/nitrogen/nitrogen-1.6.1-r1.ebuild | 52 ++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 x11-misc/nitrogen/nitrogen-1.6.1-r1.ebuild

(limited to 'x11-misc/nitrogen')

diff --git a/x11-misc/nitrogen/nitrogen-1.6.1-r1.ebuild b/x11-misc/nitrogen/nitrogen-1.6.1-r1.ebuild
new file mode 100644
index 000000000000..a43c24a1d2b3
--- /dev/null
+++ b/x11-misc/nitrogen/nitrogen-1.6.1-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools flag-o-matic gnome2-utils xdg-utils
+
+DESCRIPTION="A background browser and setter for X"
+HOMEPAGE="https://github.com/l3ib/nitrogen"
+SRC_URI="${HOMEPAGE}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="nls xinerama"
+
+RDEPEND="
+	>=dev-cpp/gtkmm-2.10:2.4
+	>=gnome-base/librsvg-2.20:2
+	>=x11-libs/gtk+-2.10:2
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	xinerama? ( x11-base/xorg-proto )
+"
+
+src_prepare() {
+	default
+
+	sed -i -e '/^UPDATE_DESKTOP/s#=.*#= :#g' data/Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	append-cxxflags -std=c++11
+	econf \
+		$(use_enable nls) \
+		$(use_enable xinerama)
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
-- 
cgit v1.2.3-65-gdbad