blob: 7ec9bf8b064f74946457957d7b83f24b3cdf6a30 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit cmake-multilib
MULTILIB_WRAPPED_HEADERS+=(
/usr/include/mysql/my_config.h
)
# wrap the config script
MULTILIB_CHOST_TOOLS=( /usr/bin/mysql_config )
DESCRIPTION="C client library for MariaDB/MySQL"
HOMEPAGE="https://dev.mysql.com/downloads/connector/c/"
LICENSE="GPL-2"
SRC_URI="https://dev.mysql.com/get/Downloads/Connector-C/${P}-src.tar.gz"
S="${WORKDIR}/${P}-src"
KEYWORDS="alpha amd64 arm ~arm64 ~hppa ia64 ~mips ppc ppc64 ~s390 ~sparc x86"
SUBSLOT="18"
SLOT="0/${SUBSLOT}"
IUSE="libressl +ssl static-libs"
CDEPEND="
sys-libs/zlib:=[${MULTILIB_USEDEP}]
ssl? (
libressl? ( dev-libs/libressl:0=[${MULTILIB_USEDEP}] )
!libressl? ( dev-libs/openssl:0=[${MULTILIB_USEDEP}] )
)
"
RDEPEND="${CDEPEND}
!dev-db/mysql[client-libs(+)]
!dev-db/mysql-cluster[client-libs(+)]
!dev-db/mariadb[client-libs(+)]
!dev-db/mariadb-connector-c[mysqlcompat]
!dev-db/mariadb-galera[client-libs(+)]
!dev-db/percona-server[client-libs(+)]
"
DEPEND="${CDEPEND}"
DOCS=( README )
PATCHES=(
"${FILESDIR}/mysql_com.patch"
"${FILESDIR}/20028_all_mysql-5.6-gcc7.patch"
"${FILESDIR}/6.1.11-openssl-1.1.patch"
)
src_prepare() {
sed -i -e 's/CLIENT_LIBS/CONFIG_CLIENT_LIBS/' "${S}/scripts/CMakeLists.txt" || die
if use libressl ; then
sed -i 's/OPENSSL_MAJOR_VERSION STREQUAL "1"/OPENSSL_MAJOR_VERSION STREQUAL "2"/' \
"${S}/cmake/ssl.cmake" || die
fi
cmake-utils_src_prepare
}
multilib_src_configure() {
local mycmakeargs=(
-DINSTALL_LAYOUT=RPM
-DINSTALL_LIBDIR=$(get_libdir)
-DWITH_DEFAULT_COMPILER_OPTIONS=OFF
-DWITH_DEFAULT_FEATURE_SET=OFF
-DENABLED_LOCAL_INFILE=ON
-DMYSQL_UNIX_ADDR="${EPREFIX}/var/run/mysqld/mysqld.sock"
-DWITH_ZLIB=system
-DENABLE_DTRACE=OFF
-DWITH_SSL=$(usex ssl system bundled)
-DLIBMYSQL_OS_OUTPUT_NAME=mysqlclient
-DSHARED_LIB_PATCH_VERSION="0"
)
cmake-utils_src_configure
}
multilib_src_install_all() {
if ! use static-libs ; then
find "${ED}" -name "*.a" -delete || die
fi
}
pkg_preinst() {
if [[ -z ${REPLACING_VERSIONS} && -e "${EROOT}usr/$(get_libdir)/libmysqlclient.so" ]] ; then
elog "Due to ABI changes when switching between different client libraries,"
elog "revdep-rebuild must find and rebuild all packages linking to libmysqlclient."
elog "Please run: revdep-rebuild --library libmysqlclient.so.${SUBSLOT}"
ewarn "Failure to run revdep-rebuild may cause issues with other programs or libraries"
fi
}
|
GitWeb