blob: 0ac6235da1565f651309d2cc0d70428c2470ce46 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_TEST="true"
KFMIN=5.86.0
PVCUT=$(ver_cut 1-3)
QTMIN=5.15.2
inherit ecm kde.org
DESCRIPTION="KDE Plasma applet for NetworkManager"
LICENSE="GPL-2 LGPL-2.1"
SLOT="5"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
IUSE="modemmanager openconnect teamd"
DEPEND="
>=app-crypt/qca-2.3.0:2
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=kde-frameworks/kcompletion-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kdbusaddons-${KFMIN}:5
>=kde-frameworks/kdeclarative-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/kitemviews-${KFMIN}:5
>=kde-frameworks/knotifications-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/kwallet-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
>=kde-frameworks/networkmanager-qt-${KFMIN}:5[teamd=]
>=kde-frameworks/plasma-${KFMIN}:5
>=kde-frameworks/solid-${KFMIN}:5
net-misc/networkmanager[teamd=]
modemmanager? (
>=dev-qt/qtxml-${QTMIN}:5
>=kde-frameworks/modemmanager-qt-${KFMIN}:5
net-misc/mobile-broadband-provider-info
)
openconnect? (
>=dev-qt/qtxml-${QTMIN}:5
net-vpn/networkmanager-openconnect
net-vpn/openconnect:=
)
"
RDEPEND="${DEPEND}
>=dev-qt/qtquickcontrols-${QTMIN}:5
>=dev-qt/qtquickcontrols2-${QTMIN}:5
>=kde-frameworks/kirigami-${KFMIN}:5
>=kde-plasma/kde-cli-tools-${PVCUT}:5
"
BDEPEND="virtual/pkgconfig"
src_prepare() {
ecm_src_prepare
# TODO: try to get a build switch upstreamed
if ! use openconnect; then
sed -e "s/^pkg_check_modules.*openconnect/#&/" -i CMakeLists.txt || die
fi
}
src_configure() {
local mycmakeargs=(
-DDISABLE_MODEMMANAGER_SUPPORT=$(usex !modemmanager)
$(cmake_use_find_package modemmanager KF5ModemManagerQt)
)
ecm_src_configure
}
pkg_postinst() {
ecm_pkg_postinst
if ! has_version "kde-plasma/plasma-workspace:5"; then
elog "${PN} is not terribly useful without kde-plasma/plasma-workspace:5."
elog "However, the networkmanagement KCM can be called from either systemsettings"
elog "or manually: $ kcmshell5 kcm_networkmanagement"
fi
}
|
GitWeb