blob: 4d87f5164edd11c7ff34202ff3b78c16844a257e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python{2_7,3_4,3_5} )
inherit eutils python-single-r1
DESCRIPTION="Unit conversion program"
HOMEPAGE="https://www.gnu.org/software/units/units.html"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
LICENSE="FDL-1.3 GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="+units_cur"
REQUIRED_USE="units_cur? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="
sys-libs/readline:=
units_cur? (
${PYTHON_DEPS}
dev-python/future[${PYTHON_USEDEP}]
)
"
DEPEND="
${RDEPEND}
"
pkg_setup() {
use units_cur && python-single-r1_pkg_setup
}
src_configure() {
econf ac_cv_path_PYTHON=no
}
src_compile() {
emake ${PN}
}
src_install() {
emake DESTDIR="${D}" install
dodoc ChangeLog NEWS README
# we're intentionally delaying this since 'make install' would
# get confused if we shove 'units_cur' there, and there is no real
# need to add more complexity for it
if use units_cur; then
sed \
-e "/^outfile/s|'.*'|'/usr/share/units/currency.units'|g" \
-e 's|^#!|&/usr/bin/python|g' \
units_cur_inst > units_cur || die
python_doscript units_cur
fi
}
|
GitWeb
