blob: e267ce5d895f6b0a79a959acc15b21cc5e0d42e4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit toolchain-funcs flag-o-matic multilib
DESCRIPTION="Simulate keyboard input and mouse activity, move and resize windows"
HOMEPAGE="http://www.semicomplete.com/projects/xdotool/"
SRC_URI="https://github.com/jordansissel/xdotool/releases/download/v${PV}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 arm ~ppc x86"
IUSE="examples"
RDEPEND="x11-libs/libXtst
x11-libs/libX11
x11-libs/libXinerama
x11-libs/libxkbcommon"
DEPEND="${RDEPEND}"
# The test wants to manualy start Xvfb, wont use VirtualX and it tries
# to run a full gnome-session. For such a tiny application i consider
# it overkill to rewrite the test scripts to not use it's own X server
# and add a full blown gnome just to run the tests.
RESTRICT="test"
src_prepare() {
default
sed -i \
-e "s/installheader post-install$/installheader/" \
-e 's:\<pkg-config\>:$(PKG_CONFIG):' \
Makefile || die "sed failed"
}
src_compile() {
tc-export CC LD PKG_CONFIG
default
}
src_install() {
emake PREFIX="${D}usr" INSTALLMAN="${D}usr/share/man" INSTALLLIB="${D}usr/$(get_libdir)" install
dodoc CHANGELIST README
if use examples; then
insinto /usr/share/doc/${PF}/examples
doins examples/*
fi
}
|
GitWeb
