osgEarth-9999 added

1 files changed, 76 insertions, 0 deletions

diff --git a/sci-geosciences/osgearth/osgearth-9999.ebuild b/sci-geosciences/osgearth/osgearth-9999.ebuild
new file mode 100644
index 0000000..7345101
--- /dev/null
+++ b/sci-geosciences/osgearth/osgearth-9999.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/osgearth/osgearth-2.6.ebuild,v 1.1 2014/10/10 20:18:46 hasufell Exp $
+
+EAPI=5
+
+inherit cmake-utils
+
+DESCRIPTION="Dynamic map generation toolkit for OpenSceneGraph"
+HOMEPAGE="http://osgearth.org/"
+
+if [[ "${PV}" = "9999" ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://github.com/Displacer/osgearth.git"
+else
+        SRC_URI="https://github.com/gwaldron/osgearth/archive/${P}.tar.gz"
+        S=${WORKDIR}/${PN}-${P}
+fi
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc qt4"
+
+RDEPEND="
+	dev-db/sqlite:3
+	>=dev-games/openscenegraph-3.2.1[curl,qt4?]
+	dev-libs/tinyxml
+	net-misc/curl
+	sci-libs/gdal
+	sci-libs/geos
+	sys-libs/zlib[minizip]
+	virtual/opengl
+	x11-libs/libX11
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtgui:4
+		dev-qt/qtopengl:4
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( dev-python/sphinx )"
+
+#PATCHES=( "${FILESDIR}"/${P}-{cmake-options}.patch )
+
+src_configure() {
+	# V8 disabled due to
+	# https://github.com/gwaldron/osgearth/issues/333
+	local mycmakeargs=(
+		-DWITH_EXTERNAL_TINYXML=ON
+		$(cmake-utils_use qt4 OSGEARTH_USE_QT)
+		-DOSGEARTH_USE_V8=OFF
+		-DOSGEARTH_USE_JAVASCRIPTCORE=OFF
+		-DOSGEARTH_USE_LIBNOISE=OFF
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	if use doc ; then
+		emake -C "${S}"/docs man html info
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use doc ; then
+		dohtml -r "${S}"/docs/build/html/*
+		doman "${S}"/docs/build/man/*
+		doinfo "${S}"/docs/build/texinfo/*.info*
+	fi
+}