# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"
JAVA_PKG_IUSE="doc source examples"

inherit eutils java-pkg-2 java-ant-2

DESCRIPTION="Annogen is a tool which helps you work with JSR175 annotations"
HOMEPAGE="http://annogen.codehaus.org/"
SRC_URI="http://dist.codehaus.org/${PN}/distributions/${P}.zip"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"

IUSE=""

CDEPEND="java-virtuals/stax-api:0
	dev-java/ant-core:0
	java-virtuals/jdk-with-com-sun:0
	>=dev-java/qdox-1.6"

RDEPEND=">=virtual/jdk-1.5
		${CDEPEND}"
DEPEND=">=virtual/jdk-1.5
		app-arch/unzip
		${CDEPEND}"

S="${WORKDIR}"

src_unpack() {
	default
	unzip -o -q "${S}/${PN}-src-${PV}.zip"
}

java_prepare() {
	find -name '*.jar' -exec rm -v {} +
}

src_compile() {
	find org -name "*.java" > "${T}/src.list"
	ejavac -d "${S}/classes" \
		-classpath $(java-pkg_getjars stax-api,qdox-1.6,ant-core):$(java-config --tools) \
		"@${T}/src.list"
	cd "${S}/classes"
	jar -cf "${S}/${PN}.jar" * || die "failed to create jar"
}

src_install() {
	java-pkg_dojar ${PN}.jar
	#is it really needed?
	#java-pkg_register-ant-task
	use doc && java-pkg_dojavadoc docs
	use source && java-pkg_dosrc org
	use examples && java-pkg_doexamples "examples"
}