From 9229fbcf4d445583000fcaefcd3a4a1849144c6e Mon Sep 17 00:00:00 2001
From: Nicholas Fish <gentoo@seaofdirac.net>
Date: Sun, 20 May 2018 12:00:59 +0200
Subject: dev-qt/qtnetwork: add LibreSSL compatible qtnetwork-5.11.x

---
 dev-qt/qtnetwork/qtnetwork-5.11.0_rc2.ebuild | 64 ++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 dev-qt/qtnetwork/qtnetwork-5.11.0_rc2.ebuild

(limited to 'dev-qt/qtnetwork/qtnetwork-5.11.0_rc2.ebuild')

diff --git a/dev-qt/qtnetwork/qtnetwork-5.11.0_rc2.ebuild b/dev-qt/qtnetwork/qtnetwork-5.11.0_rc2.ebuild
new file mode 100644
index 0000000..2d28d8f
--- /dev/null
+++ b/dev-qt/qtnetwork/qtnetwork-5.11.0_rc2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Network abstraction library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE="bindist connman libproxy libressl networkmanager +ssl"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	>=sys-libs/zlib-1.2.5
+	connman? ( ~dev-qt/qtdbus-${PV} )
+	libproxy? ( net-libs/libproxy )
+	networkmanager? ( ~dev-qt/qtdbus-${PV} )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0=[bindist=] )
+		libressl? ( dev-libs/libressl:0= )
+	)
+"
+RDEPEND="${DEPEND}
+	connman? ( net-misc/connman )
+	networkmanager? ( net-misc/networkmanager )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-libressl.patch
+)
+
+QT5_TARGET_SUBDIRS=(
+	src/network
+	src/plugins/bearer/generic
+)
+
+QT5_GENTOO_CONFIG=(
+	libproxy
+	ssl::SSL
+	ssl::OPENSSL
+	ssl:openssl-linked:LINKED_OPENSSL
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:network
+)
+
+pkg_setup() {
+	use connman && QT5_TARGET_SUBDIRS+=(src/plugins/bearer/connman)
+	use networkmanager && QT5_TARGET_SUBDIRS+=(src/plugins/bearer/networkmanager)
+}
+
+src_configure() {
+	local myconf=(
+		$(use connman || use networkmanager && echo -dbus-linked)
+		$(qt_use libproxy)
+		$(usex ssl -openssl-linked '')
+	)
+	qt5-build_src_configure
+}
-- 
cgit v1.2.3-65-gdbad