rpy-2.8.3 - bumped package from Gentoo

X-Gentoo-Bug: 598970
X-Gentoo-Bug-URL: https://bugs.gentoo.org/show_bug.cgi?id=598970

3 files changed, 84 insertions, 0 deletions

diff --git a/dev-python/rpy/Manifest b/dev-python/rpy/Manifest
new file mode 100644
index 0000000..11e544c
--- /dev/null
+++ b/dev-python/rpy/Manifest
@@ -0,0 +1 @@
+DIST rpy2-2.8.3.tar.gz 186785 SHA256 24c2ea1c0d7321e6913d5d185efa19f29e920ff8e8afbc5c757f894f61c96873 SHA512 ce6798a1d9301e15b4974f00b4901b535899a7fc0e5d5d751b35875830796d78697987beda6c1f91945d80acaf430019614793b97470ac9a2cc6e72f702874bd WHIRLPOOL f7a772132f353511e8af305a34cfea88c9dc11ae708e528b9bc26d44f3fde0f92f6039acc65a82aabdd4ad2ef40e6021fc9783c04e2d758a859fde6db696da31
diff --git a/dev-python/rpy/metadata.xml b/dev-python/rpy/metadata.xml
new file mode 100644
index 0000000..888ad9d
--- /dev/null
+++ b/dev-python/rpy/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <longdescription lang="en">
+  RPy provides a robust Python interface to the R programming
+  language. It can manage R objects and can execute arbitrary R
+  functions. All the errors from the R language are converted to
+  Python exceptions.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">rpy2</remote-id>
+    <remote-id type="sourceforge">rpy</remote-id>
+  </upstream>
+</pkgmetadata>
diff --git a/dev-python/rpy/rpy-2.8.3.ebuild b/dev-python/rpy/rpy-2.8.3.ebuild
new file mode 100644
index 0000000..6c7f871
--- /dev/null
+++ b/dev-python/rpy/rpy-2.8.3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 eutils flag-o-matic virtualx
+
+MYSLOT=2
+MY_PN=${PN}${MYSLOT}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python interface to the R Programming Language"
+HOMEPAGE="http://rpy.sourceforge.net/ https://pypi.python.org/pypi/rpy2"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="AGPL-3 GPL-2 LGPL-2.1 MPL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+RDEPEND="
+	>=dev-lang/R-3.2
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/pandas-0.13.1[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	virtual/python-singledispatch[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? ( >=dev-lang/R-3.2[X,png] )
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+PDEPEND="dev-python/ipython[${PYTHON_USEDEP}]"
+
+# ggplot2 is an optional test dep but not in portage
+S="${WORKDIR}/${MY_P}"
+
+# Tarball absent of doc files in doc folder
+# https://bitbucket.org/rpy2/rpy2/issues/229
+
+python_prepare() {
+	if ! python_is_python3; then
+		# https://bitbucket.org/rpy2/rpy2/pull-requests/56
+		sed -e '1i# coding=utf-8' \
+			-i rpy/rinterface/tests/test_SexpClosure.py \
+			-i rpy/rinterface/tests/test_SexpEnvironment.py || die
+	fi
+}
+
+python_compile() {
+	if ! python_is_python3; then
+		local CFLAGS=${CFLAGS}
+		append-cflags -fno-strict-aliasing
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib || die
+	virtx ${PYTHON} -m 'rpy2.tests' || die
+}
+
+src_test() {
+	eshopts_push -u failglob
+	distutils-r1_src_test
+	eshopts_pop
+}