# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS=1
RESTRICT_PYTHON_ABIS="3.* *-pypy-**-jython"
DISTUTILS_SRC_TEST="py.test"
inherit distutils eutils

DESCRIPTION="A collection of helpers and mock objects for unit tests and doc tests"
HOMEPAGE="http://pypi.python.org/pypi/testfixtures/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"

KEYWORDS="~amd64 ~x86"
IUSE="doc test"

RDEPEND=""
DEPEND="${RDEPEND}
	doc? ( dev-python/sphinx )"
#	test? (  net-zope/zope-component )"

src_prepare() {
	sed -e s':SPHINXBUILD   = ../bin/sphinx-build:SPHINXBUILD   = /usr/bin/sphinx-build:' \
		-i docs/Makefile
	epatch "${FILESDIR}"/${P}-adjust_tests.patch

	# remove test that tests the stripped zope-component test_components.ComponentsTests
	rm -f testfixtures/tests/test_components.py || die
	distutils_src_prepare
}
src_compile() {
	distutils_src_compile

	# Needs abs path
	if use doc; then
		PYTHONPATH="${S}" emake -C docs html
	fi
}

src_test() {
	distutils_src_test ${PN}/tests/
}

src_install() {
	distutils_src_install
	if use doc; then
		dohtml -r docs/_build/html/
		docompress -x usr/share/doc/${P}/doctrees
		insinto usr/share/doc/${P}/
		doins -r docs/_build/doctrees/
	fi
}