# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/xac/xac-0.6_pre4.ebuild,v 1.6 2009/09/30 15:52:20 josejx Exp $

EAPI="4"
PYTHON_DEPEND="2"
inherit toolchain-funcs eutils distutils multilib

DESCRIPTION="Xorgautoconfig (xac) generates configuration files for X.org"
HOMEPAGE="http://dev.gentoo.org/~josejx/xac.html"
LICENSE="GPL-2"
KEYWORDS="~amd64 ppc ppc64 ~x86"
SLOT="0"
IUSE="livecd"
DEPEND="sys-apps/pciutils"
RDEPEND=">=dev-lang/python-2.3
		x11-base/xorg-server"
SRC_URI="mirror://gentoo/${P}.tar.bz2"
DISTUTILS_SETUP_FILES=("src|setup.py")

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	### Replace /usr/lib/xac with libdir version
	sed -i "s:/usr/lib/xac:/usr/$(get_libdir)/xac:" xac

	### Fix the x86 bios call with newer glibc
	epatch "${FILESDIR}/x86-biosfix.patch"
}

src_install() {
	distutils_src_install
	local xac_base="/usr/$(get_libdir)/xac"

	dosbin "${S}"/xac

	dodir "${xac_base}"
	insinto ${xac_base}
	doins "${S}"/py/*

	### Only install the init scripts if livecd is enabled
	if use livecd; then
		newinitd "${S}"/xac.init xac
		newconfd "${S}"/xac.conf xac
	fi

}

pkg_postinst() {
	python_mod_optimize /usr/$(get_libdir)/xac
}

pkg_postrm() {
	python_mod_cleanup /usr/$(get_libdir)/xac
}