aboutsummaryrefslogtreecommitdiff
blob: 3b72167d74273fb04af5ca5f0da4c49dfb54b562 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_1,3_2} pypy{1_9,2_0} )

inherit distutils-r1

DESCRIPTION="AMQP Messaging Framework for Python"
HOMEPAGE="http://pypi.python.org/pypi/kombu https://github.com/celery/kombu"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="amqplib doc examples test"

RDEPEND=">=dev-python/anyjson-0.3.3[${PYTHON_USEDEP}]
	amqplib? ( >=dev-python/amqplib-1.0.2[${PYTHON_USEDEP}] )
	>=dev-python/py-amqp-1.0.6[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
	test? ( dev-python/nose-cover3[${PYTHON_USEDEP}]
	>=dev-python/mock-0.7[${PYTHON_USEDEP}]
	dev-python/django[$(python_gen_usedep python{2_7,3_2})]
	>=dev-python/anyjson-0.3.3[${PYTHON_USEDEP}]
	dev-python/redis-py[${PYTHON_USEDEP}]
	dev-python/pymongo[$(python_gen_usedep 'python2_7' 'pypy{1_9,2_0}')]
	dev-python/msgpack[$(python_gen_usedep python{2_7,3_1,3_2})] )
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
	dev-python/django[$(python_gen_usedep python{2_7,3_2})]
	dev-python/beanstalkc[$(python_gen_usedep python2_7)]
	dev-python/couchdb-python[$(python_gen_usedep python2_7)] )
	dev-python/setuptools[${PYTHON_USEDEP}]"

DISTUTILS_IN_SOURCE_BUILD=1

python_compile_all() {
	if use doc; then
		emake -C docs html || die "kombu docs failed installation"
	fi
}

# wip; https://github.com/celery/kombu/issues/227; at this point upstr. maintainer established these tests 
# 'can and do' pass, acks their failing 'on Travis' and offers neither a solution nor any plan to make 1.
python_test() {
	if [[ "${EPYTHON}" == python3* ]]; then
		if [[ "${EPYTHON}" == 'python3.1' ]]; then
			einfo "python3.1 ill-equipped to run testsuite, skipped"
		else
			nosetests --py3where=build/lib -e 'test_basic_consume_registers_ack_status*' \
				-e 'test_close_resolves_connection_cycle*' -e 'test_init*' \
				-e 'test_message_to_python*' -e 'test_prepare_message*' \
				-e 'test_produce_consume*' -e 'test_produce_consume_noack*' kombu/tests \
				|| die "Tests failed under ${EPYTHON}"
		fi
	else
		nosetests -e 'test_basic_consume_registers_ack_status*' -e 'test_close_resolves_connection_cycle*' \
			-e 'test_init*' -e 'test_message_to_python*' -e 'test_prepare_message*' \
			|| die "Tests failed under ${EPYTHON}"
	fi
}

python_install_all() {
	distutils-r1_python_install_all

	if use examples; then
		docompress -x usr/share/doc/${P}/examples/
		insinto usr/share/doc/${PF}/
		doins -r examples/
	fi

	use doc && dohtml -r ./docs/.build/html/
}