x11-misc/redshift: Copy old from gentoo repo to aovid gtk+3/introspection dep

4 files changed, 97 insertions, 0 deletions

diff --git a/profiles/use.local.desc b/profiles/use.local.desc
index 4430e58e..03402aab 100644
--- a/profiles/use.local.desc
+++ b/profiles/use.local.desc
@@ -259,3 +259,4 @@ x11-libs/gtk+:broadway - Enable the GDK Broadway backend.
 x11-libs/gtk+:cloudprint - Enable printing via Google Cloud Print.
 x11-libs/gtk+:colord - Use x11-misc/colord for color management in printing
 x11-libs/motif:motif22-compatibility - Compatibility with Open Motif 2.2
+x11-misc/redshift:geoclue - Control dependency on app-misc/geoclue
diff --git a/x11-misc/redshift/Manifest b/x11-misc/redshift/Manifest
new file mode 100644
index 00000000..f592e5e4
--- /dev/null
+++ b/x11-misc/redshift/Manifest
@@ -0,0 +1 @@
+DIST redshift-1.8.tar.gz 143472 SHA256 710f09cfa3acca8db415dad31401aa9eb21bcbd69eac19710c078ae1791332eb
diff --git a/x11-misc/redshift/metadata.xml b/x11-misc/redshift/metadata.xml
new file mode 100644
index 00000000..fbfb697d
--- /dev/null
+++ b/x11-misc/redshift/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>sping@gentoo.org</email>
+  </maintainer>
+  <maintainer type="project">
+    <email>desktop-misc@gentoo.org</email>
+    <name>Gentoo Desktop Miscellaneous Project</name>
+  </maintainer>
+  <use>
+    <flag name="geoclue">Control dependency on <pkg>app-misc/geoclue</pkg></flag>
+  </use>
+  <upstream>
+    <remote-id type="github">jonls/redshift</remote-id>
+  </upstream>
+</pkgmetadata>
diff --git a/x11-misc/redshift/redshift-1.8.ebuild b/x11-misc/redshift/redshift-1.8.ebuild
new file mode 100644
index 00000000..1c5bb3b7
--- /dev/null
+++ b/x11-misc/redshift/redshift-1.8.ebuild
@@ -0,0 +1,78 @@
+# Copyright 2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+RESTRICT="mirror"
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit autotools gnome2-utils python-r1
+
+DESCRIPTION="A screen color temperature adjusting software"
+HOMEPAGE="http://jonls.dk/redshift/"
+SRC_URI="https://github.com/jonls/redshift/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="geoclue gnome gtk nls"
+
+COMMON_DEPEND=">=x11-libs/libX11-1.4
+	x11-libs/libXxf86vm
+	x11-libs/libxcb
+	geoclue? ( app-misc/geoclue:0 )
+	gnome? ( dev-libs/glib:2
+		>=gnome-base/gconf-2 )
+	gtk? ( ${PYTHON_DEPS} )"
+RDEPEND="${COMMON_DEPEND}
+	gtk? ( >=dev-python/pygtk-2[${PYTHON_USEDEP}]
+		dev-python/pyxdg[${PYTHON_USEDEP}] )"
+DEPEND="${COMMON_DEPEND}
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	eapply_user
+	eautoreconf
+}
+
+src_configure() {
+	python_setup
+
+	econf \
+		--disable-silent-rules \
+		$(use_enable nls) \
+		--enable-randr \
+		--enable-vidmode \
+		--disable-wingdi \
+		$(use_enable gnome gnome-clock) \
+		$(use_enable geoclue) \
+		$(use_enable gtk gui) \
+		--disable-ubuntu
+}
+
+_impl_specific_src_install() {
+	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
+			-C src/redshift-gtk install
+}
+
+src_install() {
+	default
+
+	if use gtk; then
+		python_foreach_impl _impl_specific_src_install
+		python_replicate_script "${D}"/usr/bin/redshift-gtk
+	fi
+
+	dosym redshift-gtk /usr/bin/gtk-redshift
+}
+
+pkg_preinst() {
+	use gtk && gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	use gtk && gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && gnome2_icon_cache_update
+}