media-video/avidemux: Version bump, keeping old

7 files changed, 491 insertions, 3 deletions

diff --git a/media-libs/avidemux-core/Manifest b/media-libs/avidemux-core/Manifest
index cfc8daf6..5fa799b2 100644
--- a/media-libs/avidemux-core/Manifest
+++ b/media-libs/avidemux-core/Manifest
@@ -1 +1,2 @@
 DIST avidemux_2.6.20.tar.gz 20172362 SHA256 03c6cb7fc9eb74688b4fcd5eb654ed7b9c4ffc717a72cc09b08a2d10cdc7ef9f
+DIST avidemux_2.7.0.tar.gz 21474504 SHA256 fe1d6b794c0d94922428ff84a931264a90c39a5ffe965e03ab7ae0ce71a2c4ad
diff --git a/media-libs/avidemux-core/avidemux-core-2.7.0.ebuild b/media-libs/avidemux-core/avidemux-core-2.7.0.ebuild
new file mode 100644
index 00000000..6fe8c352
--- /dev/null
+++ b/media-libs/avidemux-core/avidemux-core-2.7.0.ebuild
@@ -0,0 +1,123 @@
+# Copyright 2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+RESTRICT="mirror"
+inherit cmake-utils flag-o-matic
+
+DESCRIPTION="Core libraries for media-video/avidemux"
+HOMEPAGE="http://fixounet.free.fr/avidemux"
+
+# Multiple licenses because of all the bundled stuff.
+LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
+SLOT="2.6"
+IUSE="debug nls nvenc sdl system-ffmpeg vaapi vdpau video_cards_fglrx xv"
+
+if [[ ${PV} == *9999* ]] ; then
+	MY_P=$P
+	KEYWORDS=""
+	PROPERTIES="live"
+	EGIT_REPO_URI="https://github.com/mean00/${MY_P}2"
+	inherit git-r3
+else
+	MY_PN="${PN/-core/}"
+	MY_P="${MY_PN}_${PV}"
+	SRC_URI="mirror://sourceforge/${MY_PN}/${MY_PN}/${PV}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+# Trying to use virtual; ffmpeg misses aac,cpudetection USE flags now though, are they needed?
+DEPEND="
+	!<media-video/avidemux-${PV}:${SLOT}
+	dev-db/sqlite:3
+	sdl? ( media-libs/libsdl:0 )
+	system-ffmpeg? ( >=virtual/ffmpeg-9:0[mp3,theora] )
+	xv? ( x11-libs/libXv:0 )
+	vaapi? ( x11-libs/libva:0 )
+	vdpau? ( x11-libs/libvdpau:0 )
+	nvenc? ( amd64? ( media-video/nvidia_video_sdk:0 ) )
+"
+RDEPEND="
+	$DEPEND
+	nls? ( virtual/libintl:0 )
+"
+DEPEND="
+	$DEPEND
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	!system-ffmpeg? ( dev-lang/yasm[nls=] )
+"
+
+REQUIRED_USE="!amd64? ( !nvenc )"
+
+S="${WORKDIR}/${MY_P}"
+CMAKE_USE_DIR="${S}/${PN/-/_}"
+
+DOCS=( AUTHORS README )
+
+src_setup() {
+	CMAKE_MAKEFILE_GENERATOR=emake # ninja does not work, currently
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	if use system-ffmpeg ; then
+		# Preparations to support the system ffmpeg. Currently fails because it depends on files the system ffmpeg doesn't install.
+		local error="Failed to remove ffmpeg."
+
+		rm -rf cmake/admFFmpeg* cmake/ffmpeg* avidemux_core/ffmpeg_package buildCore/ffmpeg || die "${error}"
+		sed -i -e 's/include(admFFmpegUtil)//g' \
+			-e '/registerFFmpeg/d' \
+			avidemux/commonCmakeApplication.cmake || die "${error}"
+		sed -i -e 's/include(admFFmpegBuild)//g' \
+			avidemux_core/CMakeLists.txt || die "${error}"
+	fi
+}
+
+src_configure() {
+	if test-flags-CXX -std=c++14 ; then
+		append-cxxflags -std=c++14
+	elif test-flags-CXX -std=c++11 ; then
+		append-cxxflags -std=c++11
+	elif use qt4 || use qt5 ; then
+		die "For qt support a compiler with c++11 support is needed"
+	fi
+
+	# Add lax vector typing for PowerPC.
+	if use ppc || use ppc64 ; then
+		append-cflags -flax-vector-conversions
+	fi
+
+	# See bug 432322.
+	use x86 && replace-flags -O0 -O1
+
+	# Filter problematic flags
+	filter-flags -fwhole-program -flto
+
+	local mycmakeargs
+	mycmakeargs=(
+		-DAVIDEMUX_SOURCE_DIR="'${S}'"
+		-DGETTEXT="$(usex nls)"
+		-DSDL="$(usex sdl)"
+		-DLIBVA="$(usex vaapi)"
+		-DVDPAU="$(usex vdpau)"
+		-DXVBA="$(usex video_cards_fglrx)"
+		-DXVIDEO="$(usex xv)"
+		-DNVENC="$(usex nvenc)"
+	)
+
+	if use debug ; then
+		mycmakeargs+=( -DVERBOSE=1 -DCMAKE_BUILD_TYPE=Debug -DADM_DEBUG=1 )
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile -j1
+}
+
+src_install() {
+	cmake-utils_src_install -j1
+}
diff --git a/media-libs/avidemux-plugins/Manifest b/media-libs/avidemux-plugins/Manifest
index cfc8daf6..5fa799b2 100644
--- a/media-libs/avidemux-plugins/Manifest
+++ b/media-libs/avidemux-plugins/Manifest
@@ -1 +1,2 @@
 DIST avidemux_2.6.20.tar.gz 20172362 SHA256 03c6cb7fc9eb74688b4fcd5eb654ed7b9c4ffc717a72cc09b08a2d10cdc7ef9f
+DIST avidemux_2.7.0.tar.gz 21474504 SHA256 fe1d6b794c0d94922428ff84a931264a90c39a5ffe965e03ab7ae0ce71a2c4ad
diff --git a/media-libs/avidemux-plugins/avidemux-plugins-2.7.0.ebuild b/media-libs/avidemux-plugins/avidemux-plugins-2.7.0.ebuild
new file mode 100644
index 00000000..c61faad8
--- /dev/null
+++ b/media-libs/avidemux-plugins/avidemux-plugins-2.7.0.ebuild
@@ -0,0 +1,193 @@
+# Copyright 2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+RESTRICT="mirror"
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
+
+inherit cmake-utils flag-o-matic python-any-r1
+
+DESCRIPTION="Plugins for media-video/avidemux"
+HOMEPAGE="http://fixounet.free.fr/avidemux"
+
+# Multiple licenses because of all the bundled stuff.
+LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
+SLOT="2.6"
+IUSE="aac aften a52 alsa amr dcaenc debug dts fdk fontconfig fribidi jack lame libsamplerate cpu_flags_x86_mmx nvenc opengl opus oss pulseaudio qt4 qt5 vorbis truetype twolame xv xvid x264 x265 vdpau vpx"
+REQUIRED_USE="!amd64? ( !nvenc ) qt5? ( !qt4 )"
+
+MY_PN="${PN/-plugins/}"
+if [[ ${PV} == *9999* ]] ; then
+	MY_P=$P
+	KEYWORDS=""
+	PROPERTIES="live"
+	EGIT_REPO_URI="https://github.com/mean00/${MY_P}2"
+	inherit git-r3
+else
+	MY_P="${MY_PN}_${PV}"
+	SRC_URI="mirror://sourceforge/${MY_PN}/${MY_PN}/${PV}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+RDEPEND="
+	~media-libs/avidemux-core-${PV}:${SLOT}[vdpau?]
+	~media-video/avidemux-${PV}:${SLOT}[opengl?,qt4?,qt5?]
+	>=dev-lang/spidermonkey-1.5-r2:0=
+	dev-libs/libxml2:2
+	media-libs/a52dec:0
+	media-libs/libass:0=
+	media-libs/libmad:0
+	media-libs/libmp4v2:0
+	media-libs/libpng:0=
+	virtual/libiconv:0
+	aac? (
+		media-libs/faac:0
+		media-libs/faad2:0
+	)
+	aften? ( media-libs/aften:0 )
+	alsa? ( >=media-libs/alsa-lib-1.0.3b-r2:0 )
+	amr? ( media-libs/opencore-amr:0 )
+	dcaenc? ( media-sound/dcaenc:0 )
+	dts? ( media-libs/libdca:0 )
+	fdk? ( media-libs/fdk-aac:0 )
+	fontconfig? ( media-libs/fontconfig:1.0 )
+	fribidi? ( dev-libs/fribidi:0 )
+	jack? (
+		media-sound/jack-audio-connection-kit:0
+		libsamplerate? ( media-libs/libsamplerate:0 )
+	)
+	lame? ( media-sound/lame:0 )
+	nvenc? ( amd64? ( media-video/nvidia_video_sdk:0 ) )
+	opus? ( media-libs/opus:0 )
+	pulseaudio? ( media-sound/pulseaudio:0 )
+	truetype? ( media-libs/freetype:2 )
+	twolame? ( media-sound/twolame:0 )
+	x264? ( media-libs/x264:0= )
+	x265? ( media-libs/x265:0= )
+	xv? (
+		x11-libs/libX11:0
+		x11-libs/libXext:0
+		x11-libs/libXv:0
+	)
+	xvid? ( media-libs/xvid:0 )
+	vorbis? ( media-libs/libvorbis:0 )
+	vpx? ( media-libs/libvpx:0 )
+"
+DEPEND="${RDEPEND}
+	oss? ( virtual/os-headers:0 )
+	${PYTHON_DEPS}"
+
+S="${WORKDIR}/${MY_P}"
+PATCHES=( "${FILESDIR}"/${PN}-2.6.20-optional-pulse.patch )
+
+src_setup() {
+	CMAKE_MAKEFILE_GENERATOR=emake # ninja does not work, currently
+}
+
+src_prepare() {
+	default
+}
+
+src_configure() {
+	if test-flags-CXX -std=c++14 ; then
+		append-cxxflags -std=c++14
+	elif test-flags-CXX -std=c++11 ; then
+		append-cxxflags -std=c++11
+	elif use qt4 || use qt5 ; then
+		die "For qt support a compiler with c++11 support is needed"
+	fi
+
+	# Add lax vector typing for PowerPC.
+	if use ppc || use ppc64 ; then
+		append-cflags -flax-vector-conversions
+	fi
+
+	# See bug 432322.
+	use x86 && replace-flags -O0 -O1
+
+	# Filter problematic flags
+	filter-flags -fwhole-program -flto
+
+	processes="buildPluginsCommon:avidemux_plugins
+		buildPluginsCLI:avidemux_plugins"
+	if use qt4 || use qt5 ; then
+		export QT_SELECT
+		processes+=" buildPluginsQt4:avidemux_plugins"
+	fi
+
+	for process in ${processes} ; do
+		local build="${process%%:*}"
+
+		local mycmakeargs
+		mycmakeargs=(
+			-DAVIDEMUX_SOURCE_DIR="'${S}'"
+			-DPLUGIN_UI=$(echo ${build/buildPlugins/} | tr '[:lower:]' '[:upper:]')
+			-DFAAC="$(usex aac)"
+			-DFAAD="$(usex aac)"
+			-DALSA="$(usex alsa)"
+			-DAFTEN="$(usex aften)"
+			-DDCAENC="$(usex dcaenc)"
+			-DFDK_AAC="$(usex fdk)"
+			-DOPENCORE_AMRWB="$(usex amr)"
+			-DOPENCORE_AMRNB="$(usex amr)"
+			-DLIBDCA="$(usex dts)"
+			-DFONTCONFIG="$(usex fontconfig)"
+			-DJACK="$(usex jack)"
+			-DLAME="$(usex lame)"
+			-DNVENC="$(usex nvenc)"
+			-DOPUS="$(usex opus)"
+			-DOSS="$(usex oss)"
+			-DPULSEAUDIOSIMPLE="$(usex pulseaudio)"
+			-DQT4="$(usex qt4)"
+			-DFREETYPE2="$(usex truetype)"
+			-DTWOLAME="$(usex twolame)"
+			-DX264="$(usex x264)"
+			-DX265="$(usex x265)"
+			-DXVIDEO="$(usex xv)"
+			-DXVID="$(usex xvid)"
+			-DVDPAU="$(usex vdpau)"
+			-DVORBIS="$(usex vorbis)"
+			-DLIBVORBIS="$(usex vorbis)"
+			-DVPXDEC="$(usex vpx)"
+			-DUSE_EXTERNAL_LIBA52=yes
+			-DUSE_EXTERNAL_LIBASS=yes
+			-DUSE_EXTERNAL_LIBMAD=yes
+			-DUSE_EXTERNAL_LIBMP4V2=yes
+		)
+		if use qt5 ; then
+			mycmakeargs+=( -DENABLE_QT5=True )
+			QT_SELECT=5
+			qt_ext=Qt5
+			export qt_ext
+		elif use qt4 ; then
+			QT_SELECT=4
+		fi
+
+		! use debug || mycmakeargs+=(
+			-DVERBOSE=1
+			-DCMAKE_BUILD_TYPE=Debug
+			-DADM_DEBUG=1
+		)
+
+		mkdir "${S}"/${build} || die "Can't create build folder."
+
+		CMAKE_USE_DIR="${S}"/${process#*:} BUILD_DIR="${S}"/${build} cmake-utils_src_configure
+	done
+}
+
+src_compile() {
+	for process in ${processes} ; do
+		BUILD_DIR="${S}/${process%%:*}" cmake-utils_src_compile
+	done
+}
+
+src_install() {
+	for process in ${processes} ; do
+		# cmake-utils_src_install doesn't respect BUILD_DIR
+		# and there sometimes is a preinstall phase present.
+		pushd "${S}/${process%%:*}" > /dev/null || die
+			grep '^preinstall/fast' Makefile && emake DESTDIR="${D}" preinstall/fast
+			grep '^install/fast' Makefile && emake DESTDIR="${D}" install/fast
+		popd > /dev/null || die
+	done
+}
diff --git a/media-video/avidemux/Manifest b/media-video/avidemux/Manifest
index cfc8daf6..5fa799b2 100644
--- a/media-video/avidemux/Manifest
+++ b/media-video/avidemux/Manifest
@@ -1 +1,2 @@
 DIST avidemux_2.6.20.tar.gz 20172362 SHA256 03c6cb7fc9eb74688b4fcd5eb654ed7b9c4ffc717a72cc09b08a2d10cdc7ef9f
+DIST avidemux_2.7.0.tar.gz 21474504 SHA256 fe1d6b794c0d94922428ff84a931264a90c39a5ffe965e03ab7ae0ce71a2c4ad
diff --git a/media-video/avidemux/avidemux-2.7.0.ebuild b/media-video/avidemux/avidemux-2.7.0.ebuild
new file mode 100644
index 00000000..1bc9fed8
--- /dev/null
+++ b/media-video/avidemux/avidemux-2.7.0.ebuild
@@ -0,0 +1,169 @@
+# Copyright 2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+RESTRICT="mirror"
+PLOCALES="ca cs de el es fr it ja pt_BR ru sr sr@latin tr"
+
+inherit cmake-utils eutils flag-o-matic l10n
+
+DESCRIPTION="Video editor designed for simple cutting, filtering and encoding tasks"
+HOMEPAGE="http://fixounet.free.fr/avidemux"
+
+# Multiple licenses because of all the bundled stuff.
+LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
+SLOT="2.6"
+IUSE="debug opengl nls nvenc qt4 qt5 sdl vaapi vdpau video_cards_fglrx xv"
+REQUIRED_USE="qt5? ( !qt4 ) "
+
+if [[ ${PV} == *9999* ]] ; then
+	MY_P=$P
+	KEYWORDS=""
+	PROPERTIES="live"
+	EGIT_REPO_URI="git://gitorious.org/${MY_PN}2-6/${MY_P}2-6.git https://git.gitorious.org/${MY_P}2-6/${MY_P}2-6.git"
+	EGIT_REPO_URI="https://github.com/mean00/${MY_P}2"
+	inherit git-r3
+else
+	MY_P="${PN}_${PV}"
+	SRC_URI="mirror://sourceforge/${PN}/${PN}/${PV}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DEPEND="
+	~media-libs/avidemux-core-${PV}:${SLOT}[nls?,sdl?,vaapi?,vdpau?,video_cards_fglrx?,xv?,nvenc?]
+	opengl? ( virtual/opengl:0 )
+	qt4? ( >=dev-qt/qtgui-4.8.3:4 )
+	qt5? ( dev-qt/qtgui:5 )
+	vaapi? ( x11-libs/libva:0 )
+	nvenc? ( amd64? ( media-video/nvidia_video_sdk:0 ) )
+"
+RDEPEND="$DEPEND
+	nls? ( virtual/libintl:0 )
+"
+PDEPEND="~media-libs/avidemux-plugins-${PV}:${SLOT}[opengl?,qt4?,qt5?]"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( AUTHORS README )
+
+src_prepare() {
+	default
+
+	processes="buildCli:avidemux/cli"
+	if use qt4 || use qt5 ; then
+		processes+=" buildQt4:avidemux/qt4"
+	fi
+
+	for process in ${processes} ; do
+		CMAKE_USE_DIR="${S}"/${process#*:} cmake-utils_src_prepare
+	done
+
+	# Fix icon name -> avidemux-2.6.png
+	sed -i -e "/^Icon/ s:${PN}:${PN}-2.6:" ${PN}2.desktop || die "Icon name fix failed."
+
+	# The desktop file is broken. It uses avidemux2 instead of avidemux3
+	# so it will actually launch avidemux-2.5 if it is installed.
+	sed -i -e "/^Exec/ s:${PN}2:${PN}3:" ${PN}2.desktop || die "Desktop file fix failed."
+	sed -i -re '/^Exec/ s:(avidemux3_)gtk:\1qt'$(usex qt5 5 4)':' ${PN}2.desktop || die "Desktop file fix failed."
+
+	# Fix QA warnings that complain a trailing ; is missing and Application is deprecated.
+	sed -i -e 's/Application;AudioVideo/AudioVideo;/g' ${PN}2.desktop || die "Desktop file fix failed."
+
+	# Now rename the desktop file to not collide with 2.5.
+	mv ${PN}2.desktop ${PN}-2.6.desktop || die "Collision rename failed."
+
+	# Remove "Build Option" dialog because it doesn't reflect what the GUI can or has been built with. (Bug #463628)
+	sed -i -e '/Build Option/d' avidemux/common/ADM_commonUI/myOwnMenu.h || die "Couldn't remove \"Build Option\" dialog."
+
+	# Fix underlinking with gold
+	sed -i -e 's/-lm/-lXext -lm/' avidemux/qt4/CMakeLists.txt || die
+}
+
+src_configure() {
+	if test-flags-CXX -std=c++14 ; then
+		append-cxxflags -std=c++14
+	elif test-flags-CXX -std=c++11 ; then
+		append-cxxflags -std=c++11
+	fi
+
+	# Add lax vector typing for PowerPC.
+	if use ppc || use ppc64 ; then
+		append-cflags -flax-vector-conversions
+	fi
+
+	# See bug 432322.
+	use x86 && replace-flags -O0 -O1
+
+	# Filter problematic flags
+	filter-flags -ftracer -flto
+
+	local mycmakeargs=(
+		-DAVIDEMUX_SOURCE_DIR="'${S}'"
+		-DGETTEXT="$(usex nls)"
+		-DSDL="$(usex sdl)"
+		-DLIBVA="$(usex vaapi)"
+		-DVDPAU="$(usex vdpau)"
+		-DXVBA="$(usex video_cards_fglrx)"
+		-DXVIDEO="$(usex xv)"
+	)
+
+	if use qt5 ; then
+		mycmakeargs+=( -DENABLE_QT5=True )
+		QT_SELECT=5
+		qt_ext=Qt5
+		export qt_ext
+	elif use qt4 ; then
+		QT_SELECT=4
+	fi
+
+	! use debug || mycmakeargs+=(
+		-DVERBOSE=1
+		-DCMAKE_BUILD_TYPE=Debug
+		-DADM_DEBUG=1
+	)
+
+	if use qt4 || use qt5 ; then
+		append-ldflags -lXext
+		export QT_SELECT
+		processes+=" buildQt4:avidemux/qt4"
+	fi
+
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		CMAKE_USE_DIR="${S}"/${process#*:} BUILD_DIR="${build}" cmake-utils_src_configure
+	done
+}
+
+src_compile() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake-utils_src_compile
+	done
+}
+
+src_install() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake-utils_src_install
+	done
+
+	if [[ -f "${ED}"/usr/bin/avidemux3_cli ]] ; then
+		fperms +x /usr/bin/avidemux3_cli
+	fi
+
+	if [[ -f "${ED}"/usr/bin/avidemux3_jobs ]] ; then
+		fperms +x /usr/bin/avidemux3_jobs
+	fi
+
+	cd "${S}" || die "Can't enter source folder."
+	newicon ${PN}_icon.png ${PN}-2.6.png
+
+	if use qt4; then
+		fperms +x /usr/bin/avidemux3_qt4
+		domenu ${PN}-2.6.desktop
+	fi
+	if use qt5; then
+		fperms +x /usr/bin/avidemux3_qt5
+		domenu ${PN}-2.6.desktop
+	fi
+}
diff --git a/metadata/pkg_desc_index b/metadata/pkg_desc_index
index f0c47d93..4f33fdb2 100644
--- a/metadata/pkg_desc_index
+++ b/metadata/pkg_desc_index
@@ -75,11 +75,11 @@ games-rpg/m5figur-mv 2.8.2: LaTeX2e character sheet layout for the Midgard Role
 games-rpg/magus 1.3.1 1.3.3 99999999: A character generator for the popular German role playing game Midgard
 mail-client/alpine 2.00-r7: alpine is an easy to use text-based based mail and news client
 media-gfx/pqiv 2.8.5: powerful GTK based command-line image viewer with a minimal UI
-media-libs/avidemux-core 2.6.20-r1: Core libraries for media-video/avidemux
-media-libs/avidemux-plugins 2.6.20: Plugins for media-video/avidemux
+media-libs/avidemux-core 2.6.20-r1 2.7.0: Core libraries for media-video/avidemux
+media-libs/avidemux-plugins 2.6.20 2.7.0: Plugins for media-video/avidemux
 media-tv/nvtv 0.4.7-r3: TV-Out for NVidia cards
 media-tv/sundtek-tv 170805.015349-r1: Sundtek MediaTV Pro III Drivers
-media-video/avidemux 2.6.20: Video editor designed for simple cutting, filtering and encoding tasks
+media-video/avidemux 2.6.20 2.7.0: Video editor designed for simple cutting, filtering and encoding tasks
 media-video/avinfo 1.0_alpha15_p1: Utility for displaying AVI information
 media-video/video-mv 11.1: Frontends for using mplayer/mencoder, ffmpeg/libav, or tzap as video recorder
 net-dialup/accounting 1.60.45.3.1: Give statistics about dialup connections. Originally part of SuSE's smpppd