1 files changed, 0 insertions, 80 deletions
diff --git a/app-portage/eix/eix-0.32.3-r1.ebuild b/app-portage/eix/eix-0.32.3-r1.ebuild
deleted file mode 100644
index 91533008..00000000
--- a/app-portage/eix/eix-0.32.3-r1.ebuild
+++ /dev/null
@@ -1,80 +0,0 @@
-# Copyright 2016 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PLOCALES="de ru"
-inherit bash-completion-r1 l10n tmpfiles
-
-DESCRIPTION="Search and query ebuilds, portage incl. local settings, ext. overlays and more"
-HOMEPAGE="https://github.com/vaeth/eix/"
-SRC_URI="https://github.com/vaeth/eix/releases/download/v${PV}/${P}.tar.xz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-IUSE="debug +dep doc nls optimization +required-use security strong-optimization strong-security sqlite swap-remote tools"
-
-BOTHDEPEND="nls? ( virtual/libintl )
-	sqlite? ( >=dev-db/sqlite-3:= )"
-RDEPEND="${BOTHDEPEND}
-	>=app-shells/push-2.0
-	>=app-shells/quoter-3.0"
-DEPEND="${BOTHDEPEND}
-	app-arch/xz-utils
-	nls? ( sys-devel/gettext )"
-
-pkg_setup() {
-	# remove stale cache file to prevent collisions
-	local old_cache="${EROOT}var/cache/${PN}"
-	test -f "${old_cache}" && rm -f -- "${old_cache}"
-}
-
-src_prepare() {
-	sed -i -e "s'/'${EPREFIX}/'" -- "${S}"/tmpfiles.d/eix.conf || die
-	eapply_user
-}
-
-src_configure() {
-	econf \
-		$(use_with sqlite) \
-		$(use_with doc extra-doc) \
-		$(use_enable nls) \
-		$(use_enable tools separate-tools) \
-		$(use_enable security) \
-		$(use_enable optimization) \
-		$(use_enable strong-security) \
-		$(use_enable strong-optimization) \
-		$(use_enable debug debugging) \
-		$(use_enable swap-remote) \
-		$(use_with prefix always-accept-keywords) \
-		$(use_with dep dep-default) \
-		$(use_with required-use required-use-default) \
-		--with-zsh-completion \
-		--with-portage-rootpath="${ROOTPATH}" \
-		--with-eprefix-default="${EPREFIX}"
-}
-
-src_install() {
-	default
-	dobashcomp bash/eix
-	dotmpfiles tmpfiles.d/eix.conf
-	diropts -m0755
-	dodir /var/cache/eix
-	# note: portage:portage ownership may be reset to root
-	fowners root:portage "${EROOT}var/cache/${PN}"
-}
-
-pkg_postinst() {
-	local obs="${EROOT}var/cache/eix.previous"
-	if test -f "${obs}"; then
-		ewarn "Found obsolete ${obs}, please remove it"
-	fi
-	tmpfiles_process eix.conf
-}
-
-pkg_postrm() {
-	if [ -z "${REPLACED_BY_VERSION}" ]; then
-		rm -rf -- "${EROOT}var/cache/${PN}"
-	fi
-}