1 files changed, 62 insertions, 0 deletions
diff --git a/sys-fs/squashfs-tools/squashfs-tools-4.2_p20140119-r1.ebuild b/sys-fs/squashfs-tools/squashfs-tools-4.2_p20140119-r1.ebuild
new file mode 100644
index 00000000..1dbb2726
--- /dev/null
+++ b/sys-fs/squashfs-tools/squashfs-tools-4.2_p20140119-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+inherit eutils flag-o-matic toolchain-funcs
+
+DESCRIPTION="Tool for creating compressed filesystem type squashfs"
+HOMEPAGE="http://squashfs.sourceforge.net"
+SRC_URI="http://dev.gentoo.org/~jer/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~mips ~x86"
+IUSE="+xz lzma lz4 lzo xattr +progress-redirect"
+
+RDEPEND="
+	sys-libs/zlib
+	!xz? ( !lzo? ( sys-libs/zlib ) )
+	lz4? ( app-arch/lz4 )
+	lzma? ( app-arch/xz-utils )
+	lzo? ( dev-libs/lzo )
+	xattr? ( sys-apps/attr )
+	xz? ( app-arch/xz-utils )
+"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${P}/squashfs-tools"
+
+src_prepare() {
+	use progress-redirect && \
+		epatch "${FILESDIR}/${P}-progress-stderr.patch"
+	epatch_user
+}
+
+src_configure() {
+	# set up make command line variables in EMAKE_SQUASHFS_CONF
+	EMAKE_SQUASHFS_CONF=(
+		$(usex lzma LZMA_XZ_SUPPORT=1 LZMA_XS_SUPPORT=0)
+		$(usex lzo LZO_SUPPORT=1 LZO_SUPPORT=0)
+		$(usex lz4 LZ4_SUPPORT=1 LZ4_SUPPORT=0)
+		$(usex xattr XATTR_SUPPORT=1 XATTR_SUPPORT=0)
+		$(usex xz XZ_SUPPORT=1 XZ_SUPPORT=0)
+	)
+	filter-flags -fno-common
+
+	tc-export CC
+}
+
+src_compile() {
+	emake ${EMAKE_SQUASHFS_CONF[@]}
+}
+
+src_install() {
+	dobin mksquashfs unsquashfs
+}
+
+pkg_postinst() {
+	ewarn "This version of mksquashfs requires a 2.6.29 kernel or better"
+	use xz &&
+		ewarn "XZ support requires a 2.6.38 kernel or better"
+}