Updated flush. Added trickle. Some small fixes

2 files changed, 107 insertions, 0 deletions

diff --git a/media-video/miro/Manifest b/media-video/miro/Manifest
new file mode 100644
index 0000000..3dbd578
--- /dev/null
+++ b/media-video/miro/Manifest
@@ -0,0 +1,2 @@
+DIST miro-3.0.1.tar.gz 9714508 RMD160 02f7ba94cb63752e679c00687f685691043fe2ed SHA1 3b3fe543e3e14010e715a0dfd3a02c4af8288af5 SHA256 595185646f6fbc82559448fc9003be06514e5b96646d61553f29509b6198ee76
+EBUILD miro-3.0.1.ebuild 2898 RMD160 be377b6db2bc93ff9d9a20c0fc8b4323a4cb31de SHA1 2fd62f62e42f030c6219e9df9c5c56614217e3a4 SHA256 4c9fa8199f8615a7f75c1f356e5d27af5f9891194a947f145cc55aee07078c57
diff --git a/media-video/miro/miro-3.0.1.ebuild b/media-video/miro/miro-3.0.1.ebuild
new file mode 100644
index 0000000..8df0fcb
--- /dev/null
+++ b/media-video/miro/miro-3.0.1.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/miro/miro-2.5.4.ebuild,v 1.1 2010/03/05 19:24:41 volkmar Exp $
+
+EAPI="2"
+
+inherit eutils fdo-mime gnome2-utils python distutils
+
+DESCRIPTION="Open source video player and podcast client"
+HOMEPAGE="http://www.getmiro.com/"
+SRC_URI="http://ftp.osuosl.org/pub/pculture.org/${PN}/src/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="+gstreamer libnotify"
+
+CDEPEND="
+	dev-libs/boost[python]
+	dev-libs/glib:2
+	dev-python/pygobject:2
+	dev-python/pygtk:2
+	media-libs/xine-lib
+	>=net-libs/rb_libtorrent-0.14.1[python]
+	|| ( net-libs/xulrunner:1.9 net-libs/xulrunner:1.8 )
+	x11-libs/gtk+:2
+	x11-libs/libX11"
+RDEPEND="${CDEPEND}
+	gstreamer? ( dev-python/gst-python:0.10 )
+	libnotify? ( dev-python/notify-python )
+	|| ( dev-lang/python[sqlite] dev-python/pysqlite:2 )
+	dev-python/dbus-python
+	dev-python/gconf-python
+	dev-python/gtkmozembed-python
+	dev-python/pycairo"
+DEPEND="${CDEPEND}
+	>=dev-python/pyrex-0.9.6.4
+	dev-util/pkgconfig"
+
+S="${WORKDIR}/${P}/platform/gtk-x11"
+
+# NOTES:
+# it's probably not working with python-3
+# used xulrunner has to be the same as the one used for gtkmozembed-python
+# psyco can make miro speedier, add a USE flag, recommand in postinst ?
+
+# TODO:
+# create a real test suite, upstream bug 12369
+# try to have a real xine/gstreamer choice, upstream bug 12371
+
+src_prepare() {
+	# disable autoupdate
+	sed -i -e "/autoupdate/d" ../../portable/startup.py || die "sed failed"
+
+	# be sure libnotify is never used if disabled
+	if ! use libnotify; then
+		sed -i -e "s:import pynotify:import pynotifyisdisabled:" \
+			../../portable/frontends/widgets/gtk/trayicon.py \
+			plat/frontends/widgets/application.py || die "sed failed"
+	fi
+
+	# set xine as the default renderer if gstreamer is disabled
+	if ! use gstreamer; then
+		sed -i -e "s:default=u\"gstreamer\":default=u\"xine\":" \
+			plat/options.py || die "sed failed"
+	fi
+}
+
+src_test() {
+	# there is a test suite but it has been designed to be used when installed
+	# should be fixed
+	#./run.sh --unittests || die "tests failed"
+	:
+}
+
+src_install() {
+	# doing the mv now otherwise, distutils_src_install will install it
+	mv README README.gtk || die "mv failed"
+
+	distutils_src_install
+
+	# installing docs
+	dodoc README.gtk ../../{ADOPTERS,CREDITS,README} || die "dodoc failed"
+	newdoc ../../portable/frontends/cli/README README.cli || die "dodoc failed"
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	distutils_pkg_postinst
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+
+	elog "If you can't see a video or can't heard an audio,"
+	elog "enable needed media-libs/xine-lib USE flags"
+	elog "or install required gstreamer plugins"
+}
+
+pkg_postrm() {
+	distutils_pkg_postrm
+	gnome2_icon_cache_update
+}