Version bump.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A792A613)

1 files changed, 64 insertions, 0 deletions

diff --git a/www-client/dillo/dillo-3.0.4.ebuild b/www-client/dillo/dillo-3.0.4.ebuild
new file mode 100644
index 000000000000..38d1bc7f5867
--- /dev/null
+++ b/www-client/dillo/dillo-3.0.4.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/dillo/dillo-3.0.4.ebuild,v 1.1 2014/05/03 20:55:26 jer Exp $
+
+EAPI=5
+inherit eutils flag-o-matic multilib toolchain-funcs
+
+DESCRIPTION="Lean FLTK based web browser"
+HOMEPAGE="http://www.dillo.org/"
+SRC_URI="http://www.dillo.org/download/${P}.tar.bz2
+	mirror://gentoo/${PN}.png"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc +gif ipv6 +jpeg +png ssl"
+
+RDEPEND="sys-libs/zlib
+	>=x11-libs/fltk-1.3:1[-cairo]
+	jpeg? ( virtual/jpeg )
+	png? ( >=media-libs/libpng-1.2:0 )
+	ssl? ( dev-libs/openssl:0 )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}2-inbuf.patch
+}
+
+src_configure() {
+	append-ldflags "-L/usr/$(get_libdir)/fltk"
+
+	econf  \
+		$(use_enable gif) \
+		$(use_enable ipv6) \
+		$(use_enable jpeg) \
+		$(use_enable png) \
+		$(use_enable ssl) \
+		--docdir="/usr/share/doc/${PF}"
+}
+
+src_compile() {
+	emake AR=$(tc-getAR)
+	if use doc; then
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	dodir /etc
+	default
+
+	use doc && dohtml html/*
+	dodoc AUTHORS ChangeLog README NEWS
+	dodoc doc/*.txt doc/README
+
+	doicon "${DISTDIR}"/${PN}.png
+	make_desktop_entry ${PN} Dillo
+}
+
+pkg_postinst() {
+	elog "Dillo has installed a default configuration into /etc/dillo/dillorc"
+	elog "You can copy this to ~/.dillo/ and customize it"
+}