Version bump. Use python-any-r1 eclass instead of the deprecated python eclass.

(Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

3 files changed, 129 insertions, 16 deletions

diff --git a/www-client/midori/ChangeLog b/www-client/midori/ChangeLog
index 9dc849850013..fad0c0e6fcd7 100644
--- a/www-client/midori/ChangeLog
+++ b/www-client/midori/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for www-client/midori
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.100 2012/10/21 12:00:16 ssuominen Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.101 2013/02/06 12:56:37 ssuominen Exp $
+
+*midori-0.4.8 (06 Feb 2013)
+
+  06 Feb 2013; Samuli Suominen <ssuominen@gentoo.org> +midori-0.4.8.ebuild,
+  midori-9999.ebuild:
+  Version bump. Use python-any-r1 eclass instead of the deprecated python
+  eclass.
 
   21 Oct 2012; Samuli Suominen <ssuominen@gentoo.org> midori-0.4.7.ebuild,
   midori-9999.ebuild:
diff --git a/www-client/midori/midori-0.4.8.ebuild b/www-client/midori/midori-0.4.8.ebuild
new file mode 100644
index 000000000000..4df8439b6c61
--- /dev/null
+++ b/www-client/midori/midori-0.4.8.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-0.4.8.ebuild,v 1.1 2013/02/06 12:56:37 ssuominen Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+unset _live_inherits
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="git://git.xfce.org/apps/${PN}"
+	_live_inherits=git-2
+else
+	KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
+	SRC_URI="mirror://xfce/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+fi
+
+inherit eutils fdo-mime gnome2-utils python-any-r1 waf-utils ${_live_inherits}
+
+VALA_VERSION=0.18
+
+DESCRIPTION="A lightweight web browser based on WebKitGTK+"
+HOMEPAGE="http://twotoasts.de/index.php/midori/"
+
+LICENSE="LGPL-2.1 MIT"
+SLOT="0"
+IUSE="+deprecated doc gnome libnotify nls +unique zeitgeist"
+
+RDEPEND=">=dev-db/sqlite-3.6.19:3
+	>=dev-libs/glib-2.22
+	dev-libs/libxml2
+	>=net-libs/libsoup-2.34:2.4
+	x11-libs/libXScrnSaver
+	deprecated? (
+		net-libs/webkit-gtk:2
+		x11-libs/gtk+:2
+		unique? ( dev-libs/libunique:1 )
+		)
+	!deprecated? (
+		>=app-crypt/gcr-3
+		net-libs/webkit-gtk:3
+		x11-libs/gtk+:3
+		unique? ( dev-libs/libunique:3 )
+		)
+	gnome? ( >=net-libs/libsoup-gnome-2.34:2.4 )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	zeitgeist? ( >=dev-libs/libzeitgeist-0.3.14 )"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	dev-lang/vala:${VALA_VERSION}
+	dev-util/intltool
+	gnome-base/librsvg
+	doc? ( dev-util/gtk-doc )
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+
+	DOCS=( AUTHORS ChangeLog HACKING INSTALL TODO TRANSLATE )
+	HTML_DOCS=( data/faq.html data/faq.css )
+}
+
+src_unpack() {
+	if [[ ${PV} == *9999* ]]; then
+		git-2_src_unpack
+	else
+		default
+	fi
+}
+
+src_prepare() {
+	# Force disabled because we don't have this custom renamed in Portage
+	sed -i -e 's:gcr-3-gtk2:&dIsAbLe:' wscript || die
+}
+
+src_configure() {
+	strip-linguas -i po
+
+	VALAC="$(type -P valac-${VALA_VERSION})" \
+	waf-utils_src_configure \
+		--disable-docs \
+		$(use_enable doc apidocs) \
+		$(use_enable unique) \
+		$(use_enable libnotify) \
+		--disable-granite \
+		--enable-addons \
+		$(use_enable nls) \
+		$(use_enable !deprecated gtk3) \
+		$(use_enable zeitgeist)
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
diff --git a/www-client/midori/midori-9999.ebuild b/www-client/midori/midori-9999.ebuild
index 49915ec276fe..64999c49bd79 100644
--- a/www-client/midori/midori-9999.ebuild
+++ b/www-client/midori/midori-9999.ebuild
@@ -1,8 +1,10 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-9999.ebuild,v 1.44 2012/10/21 12:00:16 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-9999.ebuild,v 1.45 2013/02/06 12:56:37 ssuominen Exp $
 
-EAPI=4
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
 
 unset _live_inherits
 
@@ -14,7 +16,7 @@ else
 	SRC_URI="mirror://xfce/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
 fi
 
-inherit eutils fdo-mime gnome2-utils python waf-utils ${_live_inherits}
+inherit eutils fdo-mime gnome2-utils python-any-r1 waf-utils ${_live_inherits}
 
 VALA_VERSION=0.18
 
@@ -45,7 +47,7 @@ RDEPEND=">=dev-db/sqlite-3.6.19:3
 	libnotify? ( >=x11-libs/libnotify-0.7 )
 	zeitgeist? ( >=dev-libs/libzeitgeist-0.3.14 )"
 DEPEND="${RDEPEND}
-	|| ( dev-lang/python:2.7 dev-lang/python:2.6 )
+	${PYTHON_DEPS}
 	dev-lang/vala:${VALA_VERSION}
 	dev-util/intltool
 	gnome-base/librsvg
@@ -53,8 +55,7 @@ DEPEND="${RDEPEND}
 	nls? ( sys-devel/gettext )"
 
 pkg_setup() {
-	python_set_active_version 2
-	python_pkg_setup
+	python-any-r1_pkg_setup
 
 	DOCS=( AUTHORS ChangeLog HACKING INSTALL TODO TRANSLATE )
 	HTML_DOCS=( data/faq.html data/faq.css )
@@ -69,9 +70,6 @@ src_unpack() {
 }
 
 src_prepare() {
-	# TODO: Both zeitgeist and gcr should have ./configure switch!
-	use zeitgeist || { sed -i -e 's:zeitgeist:&dIsAbLe:' wscript || die; }
-
 	# Force disabled because we don't have this custom renamed in Portage
 	sed -i -e 's:gcr-3-gtk2:&dIsAbLe:' wscript || die
 }
@@ -82,13 +80,14 @@ src_configure() {
 	VALAC="$(type -P valac-${VALA_VERSION})" \
 	waf-utils_src_configure \
 		--disable-docs \
-		 $(use_enable doc apidocs) \
-		 $(use_enable unique) \
-		 $(use_enable libnotify) \
+		$(use_enable doc apidocs) \
+		$(use_enable unique) \
+		$(use_enable libnotify) \
+		--disable-granite \
 		--enable-addons \
 		$(use_enable nls) \
 		$(use_enable !deprecated gtk3) \
-		--disable-granite
+		$(use_enable zeitgeist)
 }
 
 pkg_preinst() {