1 files changed, 87 insertions, 0 deletions
diff --git a/app-arch/file-roller/file-roller-3.5.1.ebuild b/app-arch/file-roller/file-roller-3.5.1.ebuild
new file mode 100644
index 0000000..c9d1fe0
--- /dev/null
+++ b/app-arch/file-roller/file-roller-3.5.1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/file-roller/file-roller-3.4.2.ebuild,v 1.1 2012/05/19 23:23:02 tetromino Exp $
+
+EAPI="4"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit eutils gnome2
+
+DESCRIPTION="Archive manager for GNOME"
+HOMEPAGE="http://fileroller.sourceforge.net/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="nautilus packagekit"
+KEYWORDS="~amd64 ~arm ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux"
+
+# gdk-pixbuf used extensively in the source
+# cairo used in eggtreemultidnd.c
+# pango used in fr-window
+RDEPEND=">=dev-libs/glib-2.29.14:2
+	sys-apps/file
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.4.0:3
+	x11-libs/pango
+	nautilus? ( >=gnome-base/nautilus-3 )
+	packagekit? ( app-admin/packagekit-base )
+"
+DEPEND="${RDEPEND}
+	app-text/gnome-doc-utils
+	>=dev-util/intltool-0.40.0
+	sys-devel/gettext
+	virtual/pkgconfig"
+# eautoreconf needs:
+#	gnome-base/gnome-common
+
+pkg_setup() {
+	# --disable-debug because enabling it adds -O0 to CFLAGS
+	G2CONF="${G2CONF}
+		--disable-dependency-tracking
+		--disable-scrollkeeper
+		--disable-run-in-place
+		--disable-static
+		--disable-schemas-compile
+		--disable-debug
+		--enable-magic
+		$(use_enable nautilus nautilus-actions)
+		$(use_enable packagekit)"
+	DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README TODO"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Use absolute path to GNU tar since star doesn't have the same
+	# options. On Gentoo, star is /usr/bin/tar, GNU tar is /bin/tar
+	epatch "${FILESDIR}"/${PN}-2.10.3-use_bin_tar.patch
+
+	# File providing Gentoo package names for various archivers
+	cp -f "${FILESDIR}/3.1.2-packages.match" data/packages.match || die
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	elog "${PN} is a frontend for several archiving utilities. If you want a"
+	elog "particular achive format support, see ${HOMEPAGE}"
+	elog "and install the relevant package."
+	elog
+	elog "for example:"
+	elog "  7-zip   - app-arch/p7zip"
+	elog "  ace     - app-arch/unace"
+	elog "  arj     - app-arch/arj"
+	elog "  cpio    - app-arch/cpio"
+	elog "  deb     - app-arch/dpkg"
+	elog "  iso     - app-cdr/cdrtools"
+	elog "  jar,zip - app-arch/zip and app-arch/unzip"
+	elog "  lha     - app-arch/lha"
+	elog "  lzma    - app-arch/xz-utils"
+	elog "  lzop    - app-arch/lzop"
+	elog "  rar     - app-arch/unrar"
+	elog "  rpm     - app-arch/rpm"
+	elog "  unstuff - app-arch/stuffit"
+	elog "  zoo     - app-arch/zoo"
+}