media-gfx/eog-plugins: 3.16.1-r1 → 3.26.2

Translation updates. Switch from intltool to gettext.

Package-Manager: Portage-2.3.40, Repoman-2.3.9
Manifest-Sign-Key: 0x5A56C8CD0C13248A

3 files changed, 100 insertions, 0 deletions

diff --git a/media-gfx/eog-plugins/Manifest b/media-gfx/eog-plugins/Manifest
new file mode 100644
index 00000000..0da0ff5c
--- /dev/null
+++ b/media-gfx/eog-plugins/Manifest
@@ -0,0 +1,23 @@
+-----BEGIN PGP SIGNED MESSAGE-----
+Hash: SHA256
+
+DIST eog-plugins-3.26.2.tar.xz 469072 BLAKE2B b884b4b60711909324b03737fbe4ad2068891030d1324ab5ea45ad3ae686a8b009038ffa914d3e1346cbd7297b118567eafdd9febdc25b444805a508b921b848 SHA512 a52de581135f370c0f3914910eeb5852397a1e91eca8f23ac1a138e8f6f71e639a0395f0abbd67d8682daba65924ebfeccd7d1f00af9a8adbbdd25b424fed7b9
+-----BEGIN PGP SIGNATURE-----
+Version: GnuPG v2
+
+iQKTBAEBCAB9FiEEX+aBqe7MmoWBwzA1lSmjXZiBxnkFAlsSVVVfFIAAAAAALgAo
+aXNzdWVyLWZwckBub3RhdGlvbnMub3BlbnBncC5maWZ0aGhvcnNlbWFuLm5ldDVG
+RTY4MUE5RUVDQzlBODU4MUMzMzAzNTk1MjlBMzVEOTg4MUM2NzkACgkQlSmjXZiB
+xnnQ/A/+PLMbQLG22UururrRpB/BHeLU6De/WZ4IouEGVOsconGkBYam5RurVzJA
+7P6pRVMo9jmV/vyWMNM3aggFIje35H8ovG48CxsaUQ5hdShkHN6r6G9CZV6EBAfI
+BmlWtAC4ItRbuBibWaP6hpCRO2X5XrsW4MBb2LyjFGk5HaBE7RQozdoYq7GIUuoy
+nim1reVtn/F00wmYmqopUqG1OB9drZB/w8fg9Y3C28lz7v9JuSKuZy1Ct6igoYed
+lUY/ZIcFC8771xxYa48+yv23cnunZ6+mwgBSmF2ID+imjYlFsE+mxwB8iOoVEE1c
+Al6yeJyrrZ+XI82rcVRnNevm2BMJCQLnAFEk8jAwkzWkxyBRaN26v7T6KbAqTHXa
+DRYCvFa1nggyGeLkMNCmroDbgxMY30nov/ep11cg/F+gxeMlvH40mJsD6vwYOLnP
+QdMRdJie3tGXBEEAkyK8cnMromVnata20nd6FxhV1yjLAbud3kYqCR3k/k0UYNAl
+ir6P1niEDgja9gE01RbS79bJ+WmrTDVodga7rz5Q4AkJuD5wojTBkDNMiSYz2g1i
+nfc7fxLhVzJKblKyZkjBW+aXwk+o/O4/ODq2PsxPv5EOj/NIm5BMIsDXZ8zgfrjS
+7+UqblIh8CiaGqyFUifHNzPDiBNdbyYSZLHaMqbD0lkNnKHy2yM=
+=x7LF
+-----END PGP SIGNATURE-----
diff --git a/media-gfx/eog-plugins/eog-plugins-3.26.2.ebuild b/media-gfx/eog-plugins/eog-plugins-3.26.2.ebuild
new file mode 100644
index 00000000..e08eaddb
--- /dev/null
+++ b/media-gfx/eog-plugins/eog-plugins-3.26.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{3_4,3_5,3_6} )
+
+inherit gnome2 python-single-r1
+
+DESCRIPTION="Eye of GNOME plugins"
+HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome/Plugins"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="+exif map picasa +python"
+REQUIRED_USE="
+	map? ( exif )
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/libpeas-0.7.4:=
+	>=media-gfx/eog-3.15.90
+	>=x11-libs/gtk+-3.14:3
+	exif? ( >=media-libs/libexif-0.6.16 )
+	map? (
+		media-libs/libchamplain:0.12[gtk]
+		>=media-libs/clutter-1.9.4:1.0
+		>=media-libs/clutter-gtk-1.1.2:1.0 )
+	picasa? ( >=dev-libs/libgdata-0.9.1:= )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-libs/glib-2.32:2[dbus]
+		dev-libs/libpeas:=[gtk,python,${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		gnome-base/gsettings-desktop-schemas
+		media-gfx/eog[introspection]
+		x11-libs/gtk+:3[introspection]
+		x11-libs/pango[introspection] )
+"
+# libxml2+gdk-pixbuf required for glib-compile-resources
+DEPEND="${RDEPEND}
+	dev-libs/libxml2:2
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+	x11-libs/gdk-pixbuf:2
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local plugins="fit-to-width,send-by-mail,hide-titlebar,light-theme"
+	use exif && plugins="${plugins},exif-display"
+	use map && plugins="${plugins},map"
+	use picasa && plugins="${plugins},postasa"
+	use python && plugins="${plugins},slideshowshuffle,pythonconsole,fullscreenbg,export-to-folder,maximize-windows"
+	gnome2_src_configure \
+		$(use_enable python) \
+		--with-plugins=${plugins}
+}
diff --git a/media-gfx/eog-plugins/metadata.xml b/media-gfx/eog-plugins/metadata.xml
new file mode 100644
index 00000000..3319801f
--- /dev/null
+++ b/media-gfx/eog-plugins/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+	<email>gnome@gentoo.org</email>
+	<name>Gentoo GNOME Desktop</name>
+</maintainer>
+<use>
+	<flag name="map">Enable world map display using	<pkg>media-libs/libchamplain</pkg></flag>
+	<flag name="picasa">Enable uploading to Google's Picasa Web Albums</flag>
+</use>
+</pkgmetadata>