net-libs/gnome-online-accounts: bump to 3.26.3

Mainly adds Todoist account support for GNOME Recipes and To Do.
Telepathy support is disabled by default upstream, but not sure if we
want it, or always disable.

Package-Manager: Portage-2.3.19, Repoman-2.3.6

2 files changed, 95 insertions, 0 deletions

diff --git a/net-libs/gnome-online-accounts/Manifest b/net-libs/gnome-online-accounts/Manifest
new file mode 100644
index 00000000..2502972b
--- /dev/null
+++ b/net-libs/gnome-online-accounts/Manifest
@@ -0,0 +1 @@
+DIST gnome-online-accounts-3.26.2.tar.xz 1405424 SHA256 49f8760d86fe33057eaeeb4f1667bc7f6163e428591e7aed9575563be10b17d1 SHA512 be1a9f4e1944f19937c2718db64c6968fb1f7538cdb6f7ecfa0b48136d37b1aa0c8054ff7a91cf037fac72f1e8ac7b59b69af3db39c585674113538dccf19114 WHIRLPOOL d8e8aca67ce14f5995c5d6e2a5b68c2e8ff73d7b13d72c79e57e7030eefd8124a7bdee81c36a5c9b192449d6b527d6910df4e46ee593210042ca68c28a7446bc
diff --git a/net-libs/gnome-online-accounts/gnome-online-accounts-3.26.2.ebuild b/net-libs/gnome-online-accounts/gnome-online-accounts-3.26.2.ebuild
new file mode 100644
index 00000000..0bb3bd28
--- /dev/null
+++ b/net-libs/gnome-online-accounts/gnome-online-accounts-3.26.2.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="GNOME framework for accessing online accounts"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
+
+LICENSE="LGPL-2+"
+SLOT="0/1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="debug gnome +introspection kerberos vala" # telepathy"
+REQUIRED_USE="vala? ( introspection )"
+
+# pango used in goaeditablelabel
+# libsoup used in goaoauthprovider
+# goa kerberos provider is incompatible with app-crypt/heimdal, see
+# https://bugzilla.gnome.org/show_bug.cgi?id=692250
+# json-glib-0.16 needed for bug #485092
+RDEPEND="
+	>=dev-libs/glib-2.52:2
+	>=app-crypt/libsecret-0.5
+	>=dev-libs/json-glib-0.16
+	dev-libs/libxml2:2
+	>=net-libs/libsoup-2.42:2.4
+	net-libs/rest:0.7
+	net-libs/telepathy-glib
+	>=net-libs/webkit-gtk-2.7.2:4
+	>=x11-libs/gtk+-3.19.12:3
+	x11-libs/pango
+
+	introspection? ( >=dev-libs/gobject-introspection-0.6.2:= )
+	kerberos? (
+		app-crypt/gcr:0=[gtk]
+		app-crypt/mit-krb5 )
+"
+#	telepathy? ( net-libs/telepathy-glib )
+# goa-daemon can launch gnome-control-center
+PDEPEND="gnome? ( >=gnome-base/gnome-control-center-3.2[gnome-online-accounts(+)] )"
+
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend) )
+	dev-libs/libxslt
+	>=dev-util/gtk-doc-am-1.3
+	>=dev-util/gdbus-codegen-2.30.0
+	>=dev-util/intltool-0.50.1
+	sys-devel/gettext
+	virtual/pkgconfig
+
+	dev-libs/gobject-introspection-common
+	gnome-base/gnome-common
+"
+# eautoreconf needs gobject-introspection-common, gnome-common
+
+# Due to sub-configure
+QA_CONFIGURE_OPTIONS=".*"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# TODO: Give users a way to set the G/FB/Windows Live secrets
+	# telepathy optional support is really a badly one, bug #494456
+	gnome2_src_configure \
+		--disable-static \
+		--enable-backend \
+		--enable-documentation \
+		--enable-exchange \
+		--enable-facebook \
+		--enable-flickr \
+		--enable-foursquare \
+		--enable-imap-smtp \
+		--enable-lastfm \
+		--enable-media-server \
+		--enable-owncloud \
+		--enable-pocket \
+		--enable-telepathy \
+		--enable-todoist \
+		--enable-windows-live \
+		$(usex debug --enable-debug=yes ' ') \
+		$(use_enable kerberos) \
+		$(use_enable introspection) \
+		$(use_enable vala)
+		#$(use_enable telepathy)
+	# gudev & cheese from sub-configure is overriden
+	# by top level configure, and disabled so leave it like that
+}