blob: 4a45d613ccd05d3cbdcaff27e4731fa865413b42 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
|
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
inherit eutils gnome2 readme.gentoo
if [[ ${PV} = 9999 ]]; then
inherit gnome2-live
fi
DESCRIPTION="Archive manager for GNOME"
HOMEPAGE="http://fileroller.sourceforge.net/"
LICENSE="GPL-2+ CC-BY-SA-3.0"
SLOT="0"
IUSE="nautilus packagekit"
if [[ ${PV} = 9999 ]]; then
KEYWORDS=""
else
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux"
fi
# gdk-pixbuf used extensively in the source
# cairo used in eggtreemultidnd.c
# pango used in fr-window
RDEPEND="
>=app-arch/libarchive-3:=
>=dev-libs/glib-2.36:2
>=dev-libs/json-glib-0.14
>=x11-libs/gtk+-3.9.3:3
>=x11-libs/libnotify-0.4.3:=
sys-apps/file
x11-libs/cairo
x11-libs/gdk-pixbuf:2
x11-libs/libICE
x11-libs/libSM
x11-libs/pango
nautilus? ( >=gnome-base/nautilus-3 )
packagekit? ( app-admin/packagekit-base )
"
DEPEND="${RDEPEND}
dev-util/desktop-file-utils
>=dev-util/intltool-0.40.0
sys-devel/gettext
virtual/pkgconfig
"
# eautoreconf needs:
# gnome-base/gnome-common
if [[ ${PV} = 9999 ]]; then
DEPEND="${DEPEND}
app-text/yelp-tools"
fi
DISABLE_AUTOFORMATTING="yes"
DOC_CONTENTS="
${PN} is a frontend for several archiving utilities. If you want a
particular achive format support, see ${HOMEPAGE}
and install the relevant package. For example:
7-zip - app-arch/p7zip
ace - app-arch/unace
arj - app-arch/arj
cpio - app-arch/cpio
deb - app-arch/dpkg
iso - app-cdr/cdrtools
jar,zip - app-arch/zip and app-arch/unzip
lha - app-arch/lha
lzop - app-arch/lzop
rar - app-arch/unrar or app-arch/unar
rpm - app-arch/rpm
unstuff - app-arch/stuffit
zoo - app-arch/zoo"
src_prepare() {
# Use absolute path to GNU tar since star doesn't have the same
# options. On Gentoo, star is /usr/bin/tar, GNU tar is /bin/tar
epatch "${FILESDIR}"/${PN}-2.10.3-use_bin_tar.patch
# app-arch/{un,}rar-5 support, https://bugzilla.gnome.org/show_bug.cgi?id=707568
epatch "${FILESDIR}"/${PN}-3.8.4-rar-5.patch
# File providing Gentoo package names for various archivers
cp -f "${FILESDIR}/3.6.0-packages.match" data/packages.match || die
gnome2_src_prepare
}
src_configure() {
local myconf=""
[[ ${PV} != 9999 ]] && myconf="${myconf} ITSTOOL=$(type -P true)"
DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README* TODO"
# --disable-debug because enabling it adds -O0 to CFLAGS
gnome2_src_configure \
--disable-run-in-place \
--disable-static \
--disable-debug \
--enable-magic \
--enable-libarchive \
--with-smclient=xsmp \
$(use_enable nautilus nautilus-actions) \
$(use_enable packagekit) \
${myconf}
}
src_install() {
gnome2_src_install
readme.gentoo_create_doc
}
pkg_postinst() {
gnome2_pkg_postinst
readme.gentoo_print_elog
}
|
GitWeb