blob: 351c3b1da04a8ec4a06be6bdc522b787ae5c233b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="5"
GCONF_DEBUG="no"
inherit autotools eutils gnome2
if [[ ${PV} = 9999 ]]; then
inherit gnome2-live
fi
DESCRIPTION="Help browser for GNOME"
HOMEPAGE="https://wiki.gnome.org/Apps/Yelp"
LICENSE="GPL-2+"
SLOT="0"
IUSE=""
if [[ ${PV} = 9999 ]]; then
KEYWORDS=""
else
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
fi
RDEPEND="
app-arch/bzip2:=
>=app-arch/xz-utils-4.9:=
dev-db/sqlite:3=
>=dev-libs/glib-2.38:2
>=dev-libs/libxml2-2.6.5:2
>=dev-libs/libxslt-1.1.4
>=gnome-extra/yelp-xsl-3.12
>=net-libs/webkit-gtk-1.3.10:3
>=x11-libs/gtk+-3.13.3:3
x11-themes/gnome-icon-theme-symbolic
"
DEPEND="${RDEPEND}
>=dev-util/gtk-doc-am-1.13
>=dev-util/intltool-0.41.0
>=sys-devel/gettext-0.17
virtual/pkgconfig
"
# If eautoreconf:
# gnome-base/gnome-common
if [[ ${PV} = 9999 ]]; then
DEPEND="${DEPEND}
app-text/yelp-tools
dev-util/itstool"
fi
src_prepare() {
# Fix compatibility with Gentoo's sys-apps/man
# https://bugzilla.gnome.org/show_bug.cgi?id=648854
epatch "${FILESDIR}"/${PN}-3.20.0-man-compatibility.patch
[[ ${PV} != 9999 ]] && eautoreconf
gnome2_src_prepare
}
src_configure() {
local myconf=""
[[ ${PV} != 9999 ]] && myconf="ITSTOOL=$(type -P true)"
gnome2_src_configure \
--disable-static \
--enable-bz2 \
--enable-lzma \
${myconf}
}
|
GitWeb
