1 files changed, 46 insertions, 0 deletions
diff --git a/dev-util/strace/strace-4.5.15.ebuild b/dev-util/strace/strace-4.5.15.ebuild
new file mode 100644
index 0000000..37c2817
--- /dev/null
+++ b/dev-util/strace/strace-4.5.15.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/strace/strace-4.5.15.ebuild,v 1.2 2007/02/19 04:12:57 vapier Exp $
+
+inherit flag-o-matic autotools
+
+DESCRIPTION="A useful diagnostic, instructional, and debugging tool"
+HOMEPAGE="http://sourceforge.net/projects/strace/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="as-is"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="static aio"
+
+DEPEND="aio? ( dev-libs/libaio )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	#epatch "${FILESDIR}"/${PN}-4.5.11-fbsd.patch
+
+	epatch "${FILESDIR}"/strace-dont-use-REG_SYSCALL-for-sh.patch
+	epatch "${FILESDIR}"/${PN}-4.5.12-superh-update.patch
+	epatch "${FILESDIR}"/strace-fix-arm-bad-syscall.patch
+	epatch "${FILESDIR}"/${PN}-4.5.15-mips-sprintsigmask.patch
+	epatch "${FILESDIR}"/${PN}-4.5.12-libaio.patch #103427
+	epatch "${FILESDIR}"/${PN}-4.5.15-mips-sigcontext.patch
+
+	eautoreconf
+}
+
+src_compile() {
+	filter-lfs-flags
+
+	use static && append-ldflags -static
+
+	econf $(use_enable aio libaio) || die
+	emake || die
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+	dodoc ChangeLog CREDITS NEWS PORTING README* TODO
+}