Merge branch 'master' of git@github.com:sjnewbury/multilib-overlay

Conflicts:
	dev-libs/icu/Manifest
	dev-libs/icu/icu-4.2.ebuild
	gnome-base/gnome-keyring/Manifest
	gnome-base/gnome-keyring/gnome-keyring-2.26.1-r1.ebuild
	media-libs/gst-plugins-base/Manifest
	media-libs/gst-plugins-base/gst-plugins-base-0.10.23.ebuild
	media-libs/gstreamer/Manifest
	media-libs/gstreamer/gstreamer-0.10.23.ebuild
	sys-apps/hal/Manifest
	sys-apps/hal/hal-0.5.12_rc1-r4.ebuild

2 files changed, 309 insertions, 0 deletions

diff --git a/sys-apps/hal/Manifest b/sys-apps/hal/Manifest
index 92f46570f..3b3f99782 100644
--- a/sys-apps/hal/Manifest
+++ b/sys-apps/hal/Manifest
@@ -63,9 +63,11 @@ DIST hal-0.5.11-gentoo-patches-5.tar.bz2 8890 RMD160 ffa1ae251baa8caff74f343f985
 DIST hal-0.5.11.tar.bz2 1281251 RMD160 741cfe82f0bc2d67106b24cfe526a754ab36e45f SHA1 1ddb7895d2ddc2464b553ad11f7ba38860478ae9 SHA256 78a2621209b2db4d71f25fe3a7df7b7dd4b5e866e9c699454b78e611def065cf
 DIST hal-0.5.12rc1-gentoo-patches-1.tar.bz2 3828 RMD160 3c313dd63c4f7b81bb61701222252086aeeafc1c SHA1 11d74bde76f6b03daa0afa03d3d7ccb83f8d6e27 SHA256 0f182436469223e6a2b06cfe2f2fc893f17c351075b259977f217756962a05dd
 DIST hal-0.5.12rc1-gentoo-patches-3.tar.bz2 3741 RMD160 93fbb71a9f7a0fa42f44ad4e032d00acf622447f SHA1 ccd33490e65e4ba134c88c3e1f7f7f4ba61ce7c7 SHA256 5951489f2241ae0cef1ac668fe024f97c9cdc651dac841dd18cc796073205085
+DIST hal-0.5.12rc1-gentoo-patches-4.tar.bz2 4167 RMD160 da9770ac03fe765522647f229e1b14448fd3de25 SHA1 ad27d7271a42ec5ac4c7e5935ad3cdcc719ebb3e SHA256 fd95635a3db2f7dca516b0619ca6593cf252c86dc386688a61ca57a2b4bfe3cf
 DIST hal-0.5.12rc1-gentoo-patches-5.tar.bz2 4014 RMD160 dab46cd7efb0099be1961970261ec03ea3d6291a SHA1 55a4171b6df37f89df7b9baa0a9f6c19ccb4137a SHA256 339030bf17d4fc5eb4fe42ac9b2267e4bf2a6c1f27267f0666e1f4b18e59dfae
 DIST hal-0.5.12rc1.tar.bz2 1160384 RMD160 dce660d600c18bfd910814516b675f141d369824 SHA1 1dc809e98cea0fc2f183958da24921c2eaf55edc SHA256 eeeb438dcc2a58288ed3def8c1d0076ca16f35b54d501c46f96e89da24fe38f4
 EBUILD hal-0.5.11-r8.ebuild 9002 RMD160 3e806382bdee1b294e9cd4961280c0e440aebbea SHA1 37180c316348135dec5f4a9b25bb82dd7372ea18 SHA256 91b74e7c06b41ad17d802991f14249fd50b7b41123357584c97d4ed0b27a3a94
 EBUILD hal-0.5.12_rc1-r2.ebuild 9457 RMD160 039593dd789bf8b84566aea391e64d3e859f4456 SHA1 221f849a138cd3e53f87581813607f11beea8497 SHA256 90cfce72a5873ef353febc0faa6a61b6eec537b7d67ee3abe0caee894733be1c
+EBUILD hal-0.5.12_rc1-r3.ebuild 9558 RMD160 3d33e08d70225c2d30b45a6649050638503411fb SHA1 10b4dba2bffd800fbea0e7ddf6c5f150e0fc51b5 SHA256 3129df8ad2f2adb4f22ea2e7008cbfca5e9615f827163d0fc02081b7f11b791a
 EBUILD hal-0.5.12_rc1-r4.ebuild 9591 RMD160 d8a226d5febaf9cef15955f86d682d8f62b8ce78 SHA1 bb44fe578d0a366f9cc625e61fa26ee498984dae SHA256 c849455968cd90da7c5b4770716b6c30a03cb6573d69c7bfca958af1ac07510e
 EBUILD hal-0.5.12_rc1.ebuild 9022 RMD160 d0e3ff058cfb4b37dea6c43fb63ed3f6fc5117e4 SHA1 78d3df2c0578c497eb782329d8cc68569dee3872 SHA256 e9d128e2ba1cab4ba98bac4f628842658fb142bfefaaac88b31f1226f76b8d37
diff --git a/sys-apps/hal/hal-0.5.12_rc1-r3.ebuild b/sys-apps/hal/hal-0.5.12_rc1-r3.ebuild
new file mode 100644
index 000000000..90ac89815
--- /dev/null
+++ b/sys-apps/hal/hal-0.5.12_rc1-r3.ebuild
@@ -0,0 +1,307 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/hal/hal-0.5.12_rc1.ebuild,v 1.1 2009/03/08 22:03:59 chainsaw Exp $
+
+EAPI="2"
+
+inherit eutils linux-info autotools flag-o-matic multilib-native
+
+PATCH_VERSION="4"
+
+MY_P=${P/_/}
+S=${WORKDIR}/${MY_P}
+PATCHNAME="${MY_P}-gentoo-patches-${PATCH_VERSION}"
+DESCRIPTION="Hardware Abstraction Layer"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/hal"
+SRC_URI="http://hal.freedesktop.org/releases/${MY_P}.tar.bz2
+		http://dev.gentoo.org/~dang/files/${PATCHNAME}.tar.bz2"
+
+LICENSE="|| ( GPL-2 AFL-2.0 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+
+KERNEL_IUSE="kernel_linux kernel_FreeBSD"
+IUSE="X acpi apm crypt consolekit debug dell disk-partition doc laptop policykit
+selinux ${KERNEL_IUSE}"
+
+RDEPEND=">=dev-libs/dbus-glib-0.61[lib32?]
+		 >=dev-libs/glib-2.14[lib32?]
+		 >=dev-libs/expat-1.95.8[lib32?]
+		 >=dev-libs/libusb-0.1.10a[lib32?]
+		 >=sys-apps/pciutils-2.2.7-r1[lib32?]
+		 >=dev-util/gperf-3.0.3
+		   sys-apps/usbutils
+		   virtual/eject
+		 amd64? ( >=sys-apps/dmidecode-2.7 )
+		 dell? ( >=sys-libs/libsmbios-0.13.4 )
+		 disk-partition? ( >=sys-apps/parted-1.8.0 )
+		 ia64? ( >=sys-apps/dmidecode-2.7 )
+		 kernel_linux?	(
+							>=sys-fs/udev-117[lib32?]
+							>=sys-apps/util-linux-2.13
+							>=sys-kernel/linux-headers-2.6.19
+							crypt?	( >=sys-fs/cryptsetup-1.0.5 )
+						)
+		 kernel_FreeBSD? ( >=dev-libs/libvolume_id-0.77 )
+		 x86? ( >=sys-apps/dmidecode-2.7 )
+		 selinux? ( sys-libs/libselinux sec-policy/selinux-hal )
+		 consolekit?    (
+		 					sys-auth/consolekit[policykit=]
+						)
+		 policykit?     (
+		 					sys-auth/consolekit[policykit]
+		 					sys-auth/policykit[pam]
+						)"
+DEPEND="${RDEPEND}
+		dev-util/pkgconfig
+		>=dev-util/intltool-0.35
+		doc?	(
+					app-text/xmlto
+					dev-libs/libxml2
+					dev-util/gtk-doc
+					app-text/docbook-sgml-utils
+				)"
+PDEPEND="|| (
+	>=app-misc/hal-info-20081219 )
+	!gnome-extra/hal-device-manager
+	laptop? ( >=sys-power/pm-utils-0.99.3 )"
+
+## HAL Daemon drops privledges so we need group access to read disks
+HALDAEMON_GROUPS_LINUX="haldaemon,plugdev,disk,cdrom,cdrw,floppy,usb"
+HALDAEMON_GROUPS_FREEBSD="haldaemon,plugdev,operator"
+
+function check_hotplug_net() {
+	local CONFIG_CHECK="~HOTPLUG ~NET"
+	local WARNING_HOTPLUG="CONFIG_HOTPLUG:\tis not set (required for HAL)\n"
+	local WARNING_NET="CONFIG_NET:\tis not set (required for HAL)\n"
+	check_extra_config
+}
+
+function check_inotify() {
+	local CONFIG_CHECK="~INOTIFY_USER"
+	local WARNING_INOTIFY_USER="CONFIG_INOTIFY_USER:\tis not set (required for HAL)\n"
+	check_extra_config
+}
+
+function check_acpi_proc() {
+	local CONFIG_CHECK="~ACPI_PROCFS ~ACPI_PROC_EVENT"
+	local WARNING_ACPI_PROCFS="CONFIG_ACPI_PROCFS:\tis not set (required for HAL)\n"
+	local WARNING_ACPI_PROC_EVENT="CONFIG_ACPI_PROC_EVENT:\tis not set (required for HAL)\n"
+	check_extra_config
+}
+
+pkg_setup() {
+	if use kernel_linux ; then
+		if [[ -e "${ROOT}/usr/src/linux/.config" ]] ; then
+			kernel_is ge 2 6 19 || ewarn "HAL requires a kernel version 2.6.19 or newer"
+
+			if kernel_is lt 2 6 23 && use acpi ; then
+				check_acpi_proc
+			fi
+		fi
+
+		check_hotplug_net
+		check_inotify
+	fi
+
+	# http://devmanual.gentoo.org/ebuild-writing/functions/
+	# http://bugs.gentoo.org/show_bug.cgi?id=191605
+
+	# Create groups for hotplugging and HAL
+	enewgroup haldaemon
+	enewgroup plugdev
+
+	# HAL drops priviledges by default now ...
+	# ... so we must make sure it can read disk/cdrom info (ie. be in ${HALDAEMON_GROUPS} groups)
+	if use kernel_linux; then
+		enewuser haldaemon -1 "-1" /dev/null ${HALDAEMON_GROUPS_LINUX}
+	elif use kernel_FreeBSD; then
+		enewuser haldaemon -1 "-1" /dev/null ${HALDAEMON_GROUPS_FREEBSD}
+	fi
+
+	# Make sure that the haldaemon user is in the ${HALDAEMON_GROUPS}
+	# If users have a problem with this, let them file a bug
+	if [[ ${ROOT} == / ]] ; then
+		if use kernel_linux; then
+			usermod -G ${HALDAEMON_GROUPS_LINUX} haldaemon
+		elif use kernel_FreeBSD; then
+			pw usermod haldaemon -G ${HALDAEMON_GROUPS_FREEBSD}
+		fi
+	fi
+}
+
+src_prepare() {
+	EPATCH_MULTI_MSG="Applying Gentoo Patchset ..." \
+	EPATCH_SUFFIX="patch" \
+	EPATCH_SOURCE="${WORKDIR}/${PATCHNAME}/${P}-patches/" \
+	EPATCH_FORCE="yes" \
+	epatch
+
+	eautoreconf
+}
+
+multilib-native_src_configure_internal() {
+	local acpi="$(use_enable acpi)"
+	local backend=
+	local hardware=
+	local consolekit="$(use_enable consolekit console-kit)"
+
+	append-flags -rdynamic
+
+	if use kernel_linux ; then
+		backend="linux"
+	elif use kernel_FreeBSD ; then
+		backend="freebsd"
+	else
+		eerror "Invalid backend"
+	fi
+
+	if use kernel_linux ; then
+		if use acpi ; then
+			# Using IBM ACPI and Toshiba ACPI results in double notification as this
+			# was merged into the Linux Kernel 2.6.22
+			if kernel_is lt 2 6 22 ; then
+				acpi="$acpi --enable-acpi-ibm --enable-acpi-toshiba"
+			else
+				acpi="$acpi --disable-acpi-ibm --disable-acpi-toshiba"
+			fi
+
+			acpi="$acpi --enable-acpi-proc --enable-acpi-acpid"
+		else
+			acpi="$acpi --disable-acpi-ibm --disable-acpi-toshiba"
+			acpi="$acpi --disable-acpi-proc --disable-acpi-acpid"
+		fi
+
+		hardware="--with-cpufreq --with-usb-csr --with-keymaps"
+		use arm && hardware="$hardware --with-omap --enable-pmu"
+		use ppc && hardware="$hardware --enable-pmu"
+		if use x86 || use amd64; then
+			hardware="$hardware --with-macbook --with-macbookpro"
+		fi
+
+		if use dell ; then
+			hardware="$hardware --with-dell-backlight"
+		else
+			hardware="$hardware --without-dell-backlight"
+		fi
+
+		hardware="$hardware --enable-sonypic"
+	else
+		hardware="--without-cpufreq --without-usb-csr --without-keymaps"
+		hardware="$hardware --without-omap"
+		hardware="$hardware --without-dell-backlight"
+		hardware="$hardware --enable-acpi-ibm --enable-acpi-toshiba"
+		hardware="$hardware --disable-sonypic"
+	fi
+
+	# Policykit support depends on consolekit support.  Therefore, force on
+	# consolekit, even if it's USE flag is off, if policykit support is on.
+	# This enables packages to USE-depend on hal[policykit?]
+	if use policykit ; then
+		consolekit="--enable-console-kit"
+	fi
+
+	econf --with-backend=${backend} \
+		  --with-os-type=gentoo \
+		  --with-pid-file=/var/run/hald.pid \
+		  --with-hwdata=/usr/share/misc \
+		  --with-socket-dir=/var/run/hald \
+		  --enable-umount-helper \
+		  --enable-man-pages \
+		  --disable-acl-management \
+		  --enable-pci \
+		  $(use_enable apm) \
+		  $(use_enable debug verbose-mode) \
+		  $(use_enable disk-partition parted) \
+		  $(use_enable doc docbook-docs) \
+		  $(use_enable doc gtk-doc) \
+		  $(use_enable policykit policy-kit) \
+		  ${consolekit} \
+		  --docdir=/usr/share/doc/${PF} \
+		  --localstatedir=/var \
+		  ${acpi} ${hardware} \
+	|| die "configure failed"
+}
+
+multilib-native_src_install_internal() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS ChangeLog NEWS README || die "docs failed"
+
+	# hal umount for unclean unmounts
+	exeinto /lib/udev/
+	newexe "${FILESDIR}/hal-unmount.dev" hal_unmount || die "udev helper failed"
+
+	# initscript
+	newinitd "${FILESDIR}/0.5.10-hald.rc" hald || die "init script failed"
+
+	# configuration
+	cp "${FILESDIR}/0.5.10-hald.conf" "${WORKDIR}/" || \
+		die "failed to copy hald.conf"
+
+	if use debug; then
+		sed -e 's:HALD_VERBOSE="no":HALD_VERBOSE="yes":' \
+			-i "${WORKDIR}/0.5.10-hald.conf" || die "failed to change verbose"
+	fi
+	newconfd "${WORKDIR}/0.5.10-hald.conf" hald || \
+		die "failed to install hald.conf"
+
+	if use X ; then
+		# New Configuration Snippets
+		dodoc "${WORKDIR}/${PATCHNAME}/${PN}-config-examples/"*.fdi || \
+			die "dodoc X examples failed"
+	fi
+
+	# We now create and keep /media here as both gnome-mount and pmount
+	# use these directories, to avoid collision.
+	keepdir /media
+
+	# We also need to create and keep /etc/fdi/{information,policy,preprobe}
+	# or else hal bombs.
+	keepdir /etc/hal/fdi/{information,policy,preprobe}
+
+	# HAL stores it's fdi cache in /var/cache/hald
+	keepdir /var/cache/hald
+
+	# HAL keeps its unix socket here
+	keepdir /var/run/hald
+	keepdir /var/lib/hal
+}
+
+pkg_postinst() {
+	# Despite what people keep changing this location. Either one works.. it doesn't matter
+	# http://dev.gentoo.org/~plasmaroo/devmanual/ebuild-writing/functions/
+
+	elog "The HAL daemon needs to be running for certain applications to"
+	elog "work. Suggested is to add the init script to your start-up"
+	elog "scripts, this should be done like this :"
+	elog "\`rc-update add hald default\`"
+	echo
+	elog "Looking for automounting support? Add yourself to the plugdev group"
+	echo
+	elog "IF you have additional applications which consume ACPI events, you"
+	elog "should consider installing acpid to allow applications to share ACPI"
+	elog "events."
+	if use X ; then
+		echo
+		elog "If you wish to use a non US layout, you may do so by executing:"
+		elog "setxkbmap <layout> or by utilizing your Desktop Environment's"
+		elog "Keyboard Layout Settings mechanism."
+		elog "Under GNOME, this is gnome-keyboard-properties, and under KDE"
+		elog "it is kxkb."
+	fi
+	echo
+	elog "In order have suspend/hibernate function with HAL or apps that use HAL"
+	elog "(such as gnome-power-manager), you should build HAL with the laptop"
+	elog "useflag which will install pm-utils."
+	if use X ; then
+		echo
+		elog "X Input Hotplugging (if you build xorg-server with the HAL useflag)"
+		elog "reads user specific configuration from /etc/hal/fdi/policy/."
+		echo
+		elog "You should remove the Input sections from your xorg.conf once you have"
+		elog "migrated the rules to a HAL fdi file."
+	fi
+
+	ebeep 5
+	epause 5
+}