dev-vcs/datalad: add 1.0.2HEADmaster

Signed-off-by: Horea Christian <chr@chymera.eu>

2 files changed, 80 insertions, 0 deletions

diff --git a/dev-vcs/datalad/Manifest b/dev-vcs/datalad/Manifest
index 7875ed2b6..6d9dda572 100644
--- a/dev-vcs/datalad/Manifest
+++ b/dev-vcs/datalad/Manifest
@@ -1 +1,2 @@
 DIST datalad-0.19.6.tar.gz 1420979 BLAKE2B 49d8e19449652f284f89f99e6696c6d1abf7ddcc58a8eb00004c657be38ce2532ed9c11855dca4a0a8f82c55fbf1633f53ff2bdea063fd18ad946145d27a3404 SHA512 db7cd807a8106727f0b6f587be8c0ce3abcf0dc7cf72b4757e6b44650adca05482e6b0a6c1719050fba37660dcd5de2a6f27df044a8db180ac6855ee7ff8cbda
+DIST datalad-1.0.2.tar.gz 1420919 BLAKE2B 0a5209b11cb2eaa710a423be72ad500a6b0041d7248d22be469d5e2ad7699fad30600f34f52d32c59bf069c3c5698f020fa0b7a07ce7b63e1154b548e63a6e73 SHA512 8c1bc7742687699ac21b5495b3dd6ef495da172e7c1d4e48206fd957943b18cf7c21887f4bae623b5352c34fa5e1192789b1d2a8c23883e3617e47946b8789cf
diff --git a/dev-vcs/datalad/datalad-1.0.2.ebuild b/dev-vcs/datalad/datalad-1.0.2.ebuild
new file mode 100644
index 000000000..de5b6cd6a
--- /dev/null
+++ b/dev-vcs/datalad/datalad-1.0.2.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+inherit distutils-r1 pypi
+
+DESCRIPTION="Keep code, data, containers under control with git and git-annex"
+HOMEPAGE="https://github.com/datalad/datalad"
+#SRC_URI="https://github.com/datalad/datalad/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test +downloaders +metadata +publish misc"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	app-arch/p7zip
+	app-arch/patool[${PYTHON_USEDEP}]
+	dev-python/annexremote[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	dev-python/fasteners[${PYTHON_USEDEP}]
+	dev-python/humanize[${PYTHON_USEDEP}]
+	dev-python/iso8601[${PYTHON_USEDEP}]
+	dev-python/looseversion[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/tqdm[${PYTHON_USEDEP}]
+	dev-python/wraps[${PYTHON_USEDEP}]
+	dev-vcs/git-annex
+	downloaders? (
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/keyrings-alt[${PYTHON_USEDEP}]
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	)
+	metadata? (
+		dev-python/simplejson[${PYTHON_USEDEP}]
+		dev-python/whoosh[${PYTHON_USEDEP}]
+	)
+	misc? (
+		dev-python/argcomplete[${PYTHON_USEDEP}]
+		dev-python/pyperclip[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+	)
+	publish? (
+		dev-vcs/python-gitlab[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/httpretty[${PYTHON_USEDEP}]
+		dev-python/mypy[${PYTHON_USEDEP}]
+		dev-python/vcrpy[${PYTHON_USEDEP}]
+	)
+"
+# Also wants test dep:
+# dev-python/types-requests
+# dev-python/types-python-dateutil
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	tests/test_datetimes.py::TestUnitTestMethodDecorator::test_method_decorator_works_on_unittest_kwarg_frozen_time
+	tests/test_datetimes.py::TestUnitTestMethodDecorator::test_method_decorator_works_on_unittest_kwarg_frozen_time_with_func
+	tests/test_datetimes.py::TestUnitTestMethodDecorator::test_method_decorator_works_on_unittest_kwarg_hello
+)
+
+python_test() {
+	local -x DATALAD_TESTS_NONETWORK=1
+	# see test groups in "tox.ini"
+	epytest -k "not turtle and not slow and not usecase"
+}