Added ipython-0.9.1 for testing

git-svn-id: http://overlays.gentoo.org/svn/proj/science/overlay@1306 32389bae-6d03-0410-99cf-db05cde120eb

5 files changed, 169 insertions, 0 deletions

diff --git a/dev-python/ipython/ChangeLog b/dev-python/ipython/ChangeLog
new file mode 100644
index 000000000..e072a9ada
--- /dev/null
+++ b/dev-python/ipython/ChangeLog
@@ -0,0 +1,9 @@
+# ChangeLog for dev-python/ipython
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: $
+
+  08 Oct 2008; Sébastien Fabbro <bicatali@gentoo.org>
+  +files/ipython-0.9.1-globalpath.patch, +files/62ipython-gentoo.el,
+  +metadata.xml, +ipython-0.9.1.ebuild:
+  Version bump. See bug #237878
+
diff --git a/dev-python/ipython/files/62ipython-gentoo.el b/dev-python/ipython/files/62ipython-gentoo.el
new file mode 100644
index 000000000..37b057dea
--- /dev/null
+++ b/dev-python/ipython/files/62ipython-gentoo.el
@@ -0,0 +1,4 @@
+;;; ipython site-lisp configuration
+
+(add-to-list 'load-path "@SITELISP@")
+(eval-after-load "python-mode" '(require 'ipython))
diff --git a/dev-python/ipython/files/ipython-0.9.1-globalpath.patch b/dev-python/ipython/files/ipython-0.9.1-globalpath.patch
new file mode 100644
index 000000000..6c779d45f
--- /dev/null
+++ b/dev-python/ipython/files/ipython-0.9.1-globalpath.patch
@@ -0,0 +1,11 @@
+--- IPython/Extensions/ipy_gnuglobal.py.orig	2008-09-16 17:09:05.000000000 -0400
++++ IPython/Extensions/ipy_gnuglobal.py	2008-09-16 17:09:34.000000000 -0400
+@@ -13,7 +13,7 @@
+ import os
+ 
+ # alter to your liking
+-global_bin = 'd:/opt/global/bin/global'
++global_bin = '/usr/bin/global'
+ 
+ def global_f(self,cmdline):
+     simple = 0
diff --git a/dev-python/ipython/ipython-0.9.1.ebuild b/dev-python/ipython/ipython-0.9.1.ebuild
new file mode 100644
index 000000000..f29a0ff7c
--- /dev/null
+++ b/dev-python/ipython/ipython-0.9.1.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+NEED_PYTHON=2.4
+
+inherit eutils distutils elisp-common
+
+DESCRIPTION="An advanced interactive shell for Python."
+HOMEPAGE="http://ipython.scipy.org/"
+SRC_URI="http://ipython.scipy.org/dist/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc emacs examples gnuplot readline smp test wxwindows"
+
+CDEPEND="dev-python/pexpect
+	wxwindows? ( dev-python/wxpython )
+	readline? ( sys-libs/readline )
+	emacs? ( app-emacs/python-mode virtual/emacs )
+	smp? (  net-zope/zopeinterface
+			dev-python/foolscap
+			dev-python/pyopenssl )"
+RDEPEND="${CDEPEND}
+	gnuplot? ( dev-python/gnuplot-py )"
+DEPEND="${CDEPEND}
+	test? ( dev-python/nose )"
+
+PYTHON_MODNAME="IPython"
+SITEFILE="62ipython-gentoo.el"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}"/${P}-globalpath.patch
+
+	sed -i \
+		-e '/examfiles)/d' \
+		-e '/manfiles)/d' \
+		-e '/manstatic)/d' \
+		-e 's/^docfiles.*/docfiles=""/' \
+		setup.py || die "sed failed"
+}
+
+src_compile() {
+	distutils_src_compile
+	if use emacs ; then
+		elisp-compile docs/emacs/ipython.el || die "elisp-compile failed"
+	fi
+}
+
+src_test() {
+	"${python}" setup.py \
+		install --home="${WORKDIR}/test" > /dev/null \
+		|| die "fake install for testing failed"
+	cd "${WORKDIR}"/test
+	# first initialize .ipython stuff
+	PATH="${WORKDIR}/test/bin:${PATH}" \
+		PYTHONPATH="${WORKDIR}/test/lib/python" ipython > /dev/null <<-EOF
+		EOF
+	# test ( -v for more verbosity)
+	PATH="${WORKDIR}/test/bin:${PATH}" \
+		PYTHONPATH="${WORKDIR}/test/lib/python" iptest || die "test failed"
+}
+
+src_install() {
+	DOCS="docs/source/changes.txt"
+	distutils_src_install
+
+	cd docs
+	insinto /usr/share/doc/${PF}
+
+	if use doc; then
+		doins -r dist/* || die "doc install failed"
+		doins "${S}"/IPython/Extensions/igrid_help* || die
+	fi
+
+	if use examples ; then
+		doins -r examples || die "examples install failed"
+	fi
+
+	if use emacs ; then
+		pushd emacs
+		elisp-install ${PN} ${PN}.el* || die "elisp-install failed"
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+		popd
+	fi
+}
+
+pkg_postinst() {
+	distutils_pkg_postinst
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	distutils_pkg_postrm
+	use emacs && elisp-site-regen
+}
diff --git a/dev-python/ipython/metadata.xml b/dev-python/ipython/metadata.xml
new file mode 100644
index 000000000..594d66e02
--- /dev/null
+++ b/dev-python/ipython/metadata.xml
@@ -0,0 +1,46 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>python</herd>
+<longdescription lang="en">
+IPython provides a replacement for the interactive Python interpreter with
+extra functionality.
+
+Main features:
+* Comprehensive object introspection.
+* Input history, persistent across sessions.
+* Caching of output results during a session with automatically generated
+  references.
+* Readline based name completion.
+* Extensible system of 'magic' commands for controlling the environment and
+  performing many tasks related either to IPython or the operating system.
+* Configuration system with easy switching between different setups (simpler
+  than changing $PYTHONSTARTUP environment variables every time).
+* Session logging and reloading.
+* Extensible syntax processing for special purpose situations.
+* Access to the system shell with user-extensible alias system.
+* Easily embeddable in other Python programs.
+* Integrated access to the pdb debugger and the Python profiler.
+</longdescription>
+<longdescription lang="ja">
+対話的に利用する場合にPythonインタープリタから、より機能が豊富なIPythonへ置き換>える事ができます。
+
+主機能：
+* 内包的オブジェクトの分析。
+* 入力ヒストリーはセッションを越えて記憶し続けます。
+* 出力は自動作成されるリファレンスのセッション間はキャッシュします。
+* Readlineを利用した名前補完。
+* 環境管理とIPythonまたはOSのどちらかに関係するタスク実行のためのmagic
+  コマンドを拡張可能なシステム。
+* 異なるセットアップを簡単に交換できるコンフィグレーション・システム。
+  (毎回起動時に、$PYTHONSTARTUP環境変数を指定するよりも簡単です。)
+* セッション・ロギングとセッション・リローディング。
+* 特別な状況時のための拡張可能な構文解析。
+* ユーザー定義できるエイリアス・システムでシステム・シェルにアクセス。
+* 他のPython言語プログラムを組み込むのが簡単。
+* pdbデバッガとprofilerへの統合アクセス。
+</longdescription>
+<use>
+  <flag name='smp'> Enable support for interactive parallel computing</flag>
+</use>
+</pkgmetadata>