sci-physics/genfit: Version bump 02.00.00_p20201231 snapshot.

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Oliver Freyermuth <o.freyermuth@googlemail.com>
Signed-off-by: Horea Christian <chr@chymera.eu>

1 files changed, 59 insertions, 0 deletions

diff --git a/sci-physics/genfit/genfit-02.00.00_p20201231.ebuild b/sci-physics/genfit/genfit-02.00.00_p20201231.ebuild
new file mode 100644
index 000000000..185ca5da2
--- /dev/null
+++ b/sci-physics/genfit/genfit-02.00.00_p20201231.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/GenFit/GenFit.git"
+	KEYWORDS=""
+else
+	EGIT_COMMIT="c3546c073e732abc942a08430b6ca3cb36f5339e"
+	MY_PN="GenFit"
+	SRC_URI="https://github.com/GenFit/GenFit/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${MY_PN}-${EGIT_COMMIT}"
+fi
+
+DESCRIPTION="Generic toolkit for track reconstruction in physics experiments"
+HOMEPAGE="https://github.com/GenFit/GenFit"
+
+LICENSE="LGPL-3"
+SLOT="0"
+
+IUSE="doc examples"
+
+RDEPEND="
+	sci-physics/root:=
+	dev-libs/boost:=
+"
+DEPEND="${RDEPEND}"
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_src_compile doc
+	use examples && cmake_src_compile tests
+}
+
+src_install() {
+	cmake_src_install
+	if use doc; then
+		docinto html
+		dodoc -r doc/html/.
+	fi
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r "${BUILD_DIR}/bin"
+		doins test/makeGeom.C
+		doins test/README
+	fi
+	echo
+	elog "Note that there is no support in this ebuild for RAVE yet,"
+	elog "which is also not in portage."
+	elog "It should be possible to use a local installation of RAVE"
+	elog "and set:"
+	elog "  export RAVEPATH=<yourRaveDirectory>"
+	echo
+}