4 files changed, 106 insertions, 0 deletions
diff --git a/sci-libs/asl/ChangeLog b/sci-libs/asl/ChangeLog
new file mode 100644
index 000000000..84477a053
--- /dev/null
+++ b/sci-libs/asl/ChangeLog
@@ -0,0 +1,9 @@
+# ChangeLog for sci-libs/asl
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: $
+
+*asl-0.1.4 (25 Jul 2015)
+
+  25 Jul 2015; Andrew Savchenko <bircoph@gentoo.org> +asl-0.1.4.ebuild,
+  +metadata.xml:
+  Initial commit.
diff --git a/sci-libs/asl/Manifest b/sci-libs/asl/Manifest
new file mode 100644
index 000000000..721bffbfb
--- /dev/null
+++ b/sci-libs/asl/Manifest
@@ -0,0 +1 @@
+DIST asl-0.1.4.tar.gz 11068628 SHA256 a8ec82e7ecc05911156ce08dd3f4c571c7dbc4d0dc30950cd8130a197d66da4f SHA512 8a4705abf37f82bb1e3ffd0ce0897e7077288436251dc3dbf9f5dbd5b606845e272ac7feb7091597982a636f8f3554e0161a664c8ea23cf4ee1ac6105b896039 WHIRLPOOL c1913cd16fe77dd6a204cc8dce481ad4dbccafca57d2f002dcadc8f198cdef44ca5dd220a88c3d1b1e3a5d83d3aa51c03ace74b59a6b7c0339908bead6605535
diff --git a/sci-libs/asl/asl-0.1.4.ebuild b/sci-libs/asl/asl-0.1.4.ebuild
new file mode 100644
index 000000000..15be510f1
--- /dev/null
+++ b/sci-libs/asl/asl-0.1.4.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+CMAKE_MIN_VERSION=3.0.2
+CMAKE_MAKEFILE_GENERATOR="${CMAKE_MAKEFILE_GENERATOR:-ninja}"
+
+inherit cmake-utils
+
+MY_PN=ASL
+
+DESCRIPTION="Advanced Simulation Library - multiphysics simulation software package"
+HOMEPAGE="http://asl.org.il/"
+SRC_URI="https://github.com/AvtechScientific/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples matio"
+
+RDEPEND="
+	>=dev-libs/boost-1.55:=
+	>=sci-libs/vtk-6.1
+	>=virtual/opencl-0-r2
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen[dot] )
+	matio? ( >=sci-libs/matio-1.5.2 )
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_SKIP_RPATH=yes
+		$(cmake-utils_use_with doc API_DOC)
+		$(cmake-utils_use_with examples)
+		$(cmake-utils_use_with matio)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	# examples are not installed by cmake :/
+	if use examples; then
+		local f
+		cd "${CMAKE_USE_DIR}/examples" || die
+		for f in $(find -O3 -type f -name "*.cc" -printf "%P\n" || die); do
+			cp "${f}" "${BUILD_DIR}/examples/${f%%.cc}" || die
+		done
+		cp -a input_data "${BUILD_DIR}/examples" || die
+
+		cd "${BUILD_DIR}/examples" || die
+		chmod a-x input_data/multicomponent_flow.pvsm || die
+		find -O3 -type f -name cmake_install.cmake -delete || die
+		find -O3 -type d -name CMakeFiles -exec rm -rf '{}' \+ || die
+
+		mkdir -p "${ED}/usr/share/${PN}/examples" || die
+		cp -a . "${ED}/usr/share/${PN}/examples" || die
+	fi
+}
diff --git a/sci-libs/asl/metadata.xml b/sci-libs/asl/metadata.xml
new file mode 100644
index 000000000..ab3f78dbc
--- /dev/null
+++ b/sci-libs/asl/metadata.xml
@@ -0,0 +1,31 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>sci-physics</herd>
+<maintainer>
+  <email>bircoph@gentoo.org</email>
+  <name>Andrew Savchenko</name>
+</maintainer>
+<longdescription lang="en">
+  Advanced Simulation Library (ASL) is a free and open source
+  multiphysics simulation software package. Its computational
+  engine is based, among others, on the Lattice Boltzmann Methods
+  and is written in OpenCL which enable extraordinarily efficient
+  deployment on a variety of massively parallel architectures,
+  ranging from inexpensive FPGAs, DSPs and GPUs up to heterogeneous
+  clusters and supercomputers. The engine is hidden entirely behind
+  C++ classes, so that no OpenCL knowledge is required from
+  application programmers. ASL can be utilized to model various
+  coupled physical and chemical phenomena and employed in a
+  multitude of fields: computational fluid dynamics, virtual
+  sensing, industrial process data validation and reconciliation,
+  image-guided surgery, computer-aided engineering,
+  high-performance scientific computing, etc.
+</longdescription>
+<use>
+  <flag name="matio">Matlab support with <pkg>sci-libs/matio</pkg></flag>
+</use>
+<upstream>
+  <remote-id type="github">AvtechScientific/ASL</remote-id>
+</upstream>
+</pkgmetadata>