1 files changed, 64 insertions, 0 deletions
diff --git a/app-admin/eselect/eselect-1.2.16-r1.ebuild b/app-admin/eselect/eselect-1.2.16-r1.ebuild
new file mode 100644
index 000000000..d8a2ea579
--- /dev/null
+++ b/app-admin/eselect/eselect-1.2.16-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=3
+inherit eutils bash-completion autotools
+
+DESCRIPTION="Gentoo's multi-purpose configuration and management tool"
+HOMEPAGE="http://www.gentoo.org/proj/en/eselect/"
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc"
+
+RDEPEND="sys-apps/sed
+	|| (
+		sys-apps/coreutils
+		sys-freebsd/freebsd-bin
+		app-misc/realpath
+	)"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/docutils )"
+RDEPEND="!app-admin/eselect-news
+	${RDEPEND}
+	sys-apps/file
+	sys-libs/ncurses"
+
+# Commented out: only few users of eselect will edit its source
+#PDEPEND="emacs? ( app-emacs/gentoo-syntax )
+#	vim-syntax? ( app-vim/eselect-syntax )"
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-alternatives.patch
+	eautoreconf
+}
+
+src_compile() {
+	emake || die "emake failed"
+
+	if use doc; then
+		make html || die "failed to build html"
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dodoc AUTHORS ChangeLog NEWS README TODO doc/*.txt
+	use doc && dohtml *.html doc/*
+	dobashcompletion misc/${PN}.bashcomp
+
+	# needed by news module
+	keepdir /var/lib/gentoo/news
+}
+
+pkg_postinst() {
+	# fowners in src_install doesn't work for the portage group:
+	# merging changes the group back to root
+	[[ -z ${EROOT} ]] && local EROOT=${ROOT}
+	chgrp portage "${EROOT}/var/lib/gentoo/news" \
+		&& chmod g+w "${EROOT}/var/lib/gentoo/news"
+
+	bash-completion_pkg_postinst
+}