1 files changed, 0 insertions, 79 deletions
diff --git a/dev-python/nbconvert/nbconvert-4.0.0-r1.ebuild b/dev-python/nbconvert/nbconvert-4.0.0-r1.ebuild
deleted file mode 100644
index ddbb31e64..000000000
--- a/dev-python/nbconvert/nbconvert-4.0.0-r1.ebuild
+++ /dev/null
@@ -1,79 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=5
-
-PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
-
-inherit distutils-r1
-
-MY_PN="nbconvert"
-
-DESCRIPTION="Converting Jupyter Notebooks"
-HOMEPAGE="http://jupyter.org"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-KEYWORDS="~amd64 ~x86"
-
-LICENSE="BSD"
-SLOT="0"
-IUSE="doc test"
-
-PATCHES=(
-	"${FILESDIR}/${P}"-docs-Makefile.patch
-	"${FILESDIR}/${P}"-pandoc-highlighting.patch
-)
-
-RDEPEND="
-	dev-python/jupyter_core[${PYTHON_USEDEP}]
-	dev-python/nbformat[${PYTHON_USEDEP}]
-	dev-python/mistune[${PYTHON_USEDEP}]
-	dev-python/jinja[${PYTHON_USEDEP}]
-	dev-python/pygments[${PYTHON_USEDEP}]
-	dev-python/traitlets[${PYTHON_USEDEP}]
-	"
-DEPEND="${RDEPEND}
-	doc? (
-		dev-python/ipython[${PYTHON_USEDEP}]
-		dev-python/jupyter_client[${PYTHON_USEDEP}]
-		dev-python/sphinx[${PYTHON_USEDEP}]
-		app-text/pandoc
-	)
-	test? (
-		dev-python/nose[${PYTHON_USEDEP}]
-		dev-python/coverage[${PYTHON_USEDEP}]
-		dev-python/ipykernel[${PYTHON_USEDEP}]
-	)
-	"
-
-python_prepare_all() {
-	# Prevent un-needed download during build
-	if use doc; then
-		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
-	fi
-
-	distutils-r1_python_prepare_all
-}
-
-python_compile_all() {
-	use doc && emake -C docs html
-}
-
-python_test() {
-	distutils_install_for_testing
-	cd "${TEST_DIR}"/lib || die
-	nosetests --with-coverage --cover-package=nbconvert nbconvert || die
-}
-
-python_install_all() {
-	use doc && HTML_DOCS=( docs/build/html/. )
-	distutils-r1_python_install_all
-}
-
-pkg_postinst() {
-	if ! has_version app-text/pandoc ; then
-		einfo "Pandoc is required for converting to formats other than Python,"
-		einfo "HTML, and Markdown. If you need this functionality, install"
-		einfo "app-text/pandoc."
-	fi
-}