1 files changed, 50 insertions, 0 deletions
diff --git a/dev-python/python-igraph/python-igraph-0.10.4.ebuild b/dev-python/python-igraph/python-igraph-0.10.4.ebuild
new file mode 100644
index 000000000..3ee6e1eb4
--- /dev/null
+++ b/dev-python/python-igraph/python-igraph-0.10.4.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python interface for igraph"
+HOMEPAGE="https://igraph.org"
+SRC_URI="$(pypi_sdist_url igraph)"
+S="${WORKDIR}/igraph-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-libs/igraph-$(ver_cut 1-2)
+	>=dev-python/texttable-1.6.2[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? (
+		dev-python/cairocffi[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/networkx[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/plotly[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# fix the igraph include path
+	cd src || die
+	find -type f -name "*.h" -exec sed -i -e 's@#include <igraph@#include <igraph/igraph@g' {} + || die
+	find -type f -name "*.c" -exec sed -i -e 's@#include <igraph@#include <igraph/igraph@g' {} + || die
+	cd .. || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile --use-pkg-config
+}