1 files changed, 47 insertions, 0 deletions
diff --git a/sci-chemistry/wxmacmolplt/wxmacmolplt-7.6.2.ebuild b/sci-chemistry/wxmacmolplt/wxmacmolplt-7.6.2.ebuild
new file mode 100644
index 000000000..028ff6f62
--- /dev/null
+++ b/sci-chemistry/wxmacmolplt/wxmacmolplt-7.6.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+WX_GTK_VER=3.0
+
+inherit autotools eutils wxwidgets
+
+DESCRIPTION="Chemical 3D graphics program with GAMESS input builder"
+HOMEPAGE="http://brettbode.github.io/wxmacmolplt/"
+SRC_URI="https://github.com/brettbode/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="flash"
+
+RDEPEND="
+	media-libs/glew
+	media-libs/mesa
+	x11-libs/wxGTK:${WX_GTK_VER}[X,opengl]
+	flash? ( media-libs/ming )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	epatch_user
+
+	sed \
+		-e "/^dist_doc_DATA/d" \
+		-i Makefile.am || die "Failed to disable installation of LICENSE file"
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-glew \
+		$(use_with flash ming)
+}
+
+src_install() {
+	default
+	doicon resources/${PN}.png
+	make_desktop_entry ${PN} wxMacMolPlt ${PN} "Science;DataVisualization;"
+}