1 files changed, 51 insertions, 0 deletions
diff --git a/sci-mathematics/cipi/cipi-1.0-r1.ebuild b/sci-mathematics/cipi/cipi-1.0-r1.ebuild
new file mode 100644
index 000000000..6cd189e33
--- /dev/null
+++ b/sci-mathematics/cipi/cipi-1.0-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Computing information projections iteratively"
+HOMEPAGE="https://github.com/tom111/cipi"
+SRC_URI="https://github.com/tom111/cipi/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="doc"
+
+DEPEND="
+	dev-libs/boost:=
+	doc? ( virtual/latex-base )"
+RDEPEND="${DEPEND}"
+
+DOCS="AUTHORS README"
+
+CMAKE_IN_SOURCE_BUILD="yes"
+
+PATCHES=(
+	"${FILESDIR}/${P}-boost.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+	append-ldflags -Wl,--copy-dt-needed-entries
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DENABLE_DOC=$(usex doc ON OFF)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	elog
+	elog "The sample PARAM file has been installed to /usr/share/${PN}-${PV}"
+	elog
+	if use doc; then
+		elog "A pdf manual has been installed to /usr/share/${PN}-${PV}"
+	fi
+}