blob: 02581b74c8d04840d2e070f640fcbca42bcd07b0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_10 )
DISTUTILS_USE_SETUPTOOLS=rdepend
DISTUTILS_IN_SOURCE_BUILD=1
inherit distutils-r1 optfeature
DESCRIPTION="Statistical and interactive HTML plots for Python"
HOMEPAGE="https://bokeh.org/"
SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz
https://raw.githubusercontent.com/bokeh/bokeh/${PV}/conftest.py -> conftest-${P}.py
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RDEPEND="
>=dev-python/jinja-2.9[${PYTHON_USEDEP}]
>=dev-python/numpy-1.11.3[${PYTHON_USEDEP}]
>=dev-python/packaging-16.8[${PYTHON_USEDEP}]
>=dev-python/pillow-7.1.0[${PYTHON_USEDEP}]
>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
>=dev-python/typing-extensions-3.10.0[${PYTHON_USEDEP}]
>=dev-python/tornado-5.1[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/beautifulsoup4[${PYTHON_USEDEP}]
dev-python/flaky[${PYTHON_USEDEP}]
dev-python/ipython_genutils[${PYTHON_USEDEP}]
dev-python/mock[${PYTHON_USEDEP}]
dev-python/networkx[${PYTHON_USEDEP}]
dev-python/nbconvert[${PYTHON_USEDEP}]
dev-python/nbformat[${PYTHON_USEDEP}]
dev-python/pydot[${PYTHON_USEDEP}]
dev-python/pytz[${PYTHON_USEDEP}]
dev-python/scipy[${PYTHON_USEDEP}]
dev-python/selenium[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_prepare_all(){
cp "${DISTDIR}"/conftest-${P}.py "${S}"/conftest.py || die
distutils-r1_python_prepare_all
}
python_test() {
# disable tests having network calls
local SKIP_TESTS=" \
not (test___init__ and TestWarnings and test_filters) and \
not (test_json__subcommands and test_no_script) and \
not (test_standalone and Test_autoload_static) and \
not test_nodejs_compile_javascript and \
not test_nodejs_compile_less and \
not test_inline_extension and \
not (test_model and test_select) and \
not test_tornado__server and \
not test_client_server and \
not test_webdriver and \
not test_export and \
not test_server and \
not test_bundle and \
not test_ext and \
not test_detect_current_filename \
"
epytest -m "not sampledata" tests/unit -k "${SKIP_TESTS}"
}
pkg_postinst() {
optfeature "integration with amazon S3" dev-python/boto
optfeature "pypi integration to publish packages" dev-python/twine
optfeature "js library usage" net-libs/nodejs
}
|
GitWeb