blob: 4e2b586527979be49c2d8a6366f8bc98a8bbc673 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
|
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/openmpi/openmpi-1.2.4.ebuild,v 1.2 2007/12/13 22:39:53 jsbronder Exp $
EAPI=2
inherit eutils multilib flag-o-matic toolchain-funcs fortran mpi
MY_P=${P/-mpi}
S=${WORKDIR}/${MY_P}
DESCRIPTION="A high-performance message passing library (MPI)"
HOMEPAGE="http://www.open-mpi.org"
SRC_URI="http://www.open-mpi.org/software/ompi/v1.4/downloads/${MY_P}.tar.bz2"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
RESTRICT="mpi-threads? ( test )"
IUSE="+cxx fortran heterogeneous ipv6 infiniband mpi-threads pbs romio threads vt"
RDEPEND="pbs? ( sys-cluster/torque )
vt? (
!dev-libs/libotf
!app-text/lcdf-typetools
)
infiniband? ( sys-infiniband/libibverbs )
$(mpi_imp_deplist)"
DEPEND="${RDEPEND}"
pkg_setup() {
MPI_ESELECT_FILE="eselect.mpi.openmpi"
if use mpi-threads; then
ewarn
ewarn "WARNING: use of MPI_THREAD_MULTIPLE is still disabled by"
ewarn "default and officially unsupported by upstream."
ewarn "You may stop now and set USE=-mpi-threads"
ewarn
epause 5
fi
elog
elog "OpenMPI has an overwhelming count of configuration options."
elog "Don't forget the EXTRA_ECONF environment variable can let you"
elog "specify configure options if you find them necessary."
elog
if use fortran; then
FORTRAN="g77 gfortran ifc"
fortran_pkg_setup
fi
}
src_prepare() {
# Fix --as-needed problems with f77 and f90.
sed -i 's:^libs=:libs=-Wl,--no-as-needed :' \
ompi/tools/wrappers/mpif{77,90}-wrapper-data.txt.in
# Necessary for scalibility, see
# http://www.open-mpi.org/community/lists/users/2008/09/6514.php
if use threads; then
echo 'oob_tcp_listen_mode = listen_thread' \
>> opal/etc/openmpi-mca-params.conf
fi
}
src_configure() {
local c="
--without-xgrid
--enable-pretty-print-stacktrace
--enable-orterun-prefix-by-default
--without-slurm"
if use mpi-threads; then
c="${c}
--enable-mpi-threads
--enable-progress-threads"
fi
if use fortran; then
if [[ "${FORTRANC}" = "g77" ]]; then
c="${c} --disable-mpi-f90"
elif [[ "${FORTRANC}" = if* ]]; then
# Enabled here as gfortran compile times are huge with this enabled.
c="${c} --with-mpi-f90-size=medium"
fi
else
c="${c}
--disable-mpi-f90
--disable-mpi-f77"
fi
! use vt && c="${c} --enable-contrib-no-build=vt"
econf $(mpi_econf_args) ${c} \
$(use_enable cxx mpi-cxx) \
$(use_enable romio io-romio) \
$(use_enable heterogeneous) \
$(use_with pbs tm) \
$(use_enable ipv6) \
$(use_with infiniband openib)
}
src_install () {
emake DESTDIR="${D}" install || die
mpi_dodoc README AUTHORS NEWS VERSION
mpi_imp_add_eselect
}
src_test() {
# Doesn't work with the default src_test as the dry run (-n) fails.
cd "${S}"
emake -j1 check || die "emake check failed"
}
|