games-fps/vavoom: Added also SVN 'live' ebuild

svn path=/sunrise/; revision=3841

3 files changed, 245 insertions, 1 deletions

diff --git a/games-fps/vavoom/ChangeLog b/games-fps/vavoom/ChangeLog
index 679d78661..90e26a80b 100644
--- a/games-fps/vavoom/ChangeLog
+++ b/games-fps/vavoom/ChangeLog
@@ -2,6 +2,9 @@
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
 # $Header: $
 
+  07 Jun 2007; Davide Cendron (scen) <scen@gentoo.org> +vavoom-9999.ebuild:
+  Added also SVN 'live' ebuild
+
   07 Jun 2007; Davide Cendron (scen) <scen@gentoo.org> vavoom-1.23.1.ebuild:
   Removed useless old commented lines
 
diff --git a/games-fps/vavoom/Manifest b/games-fps/vavoom/Manifest
index 565556210..37c16b7a0 100644
--- a/games-fps/vavoom/Manifest
+++ b/games-fps/vavoom/Manifest
@@ -1,4 +1,5 @@
 DIST vavoom-1.23.1.tar.bz2 1694668 RMD160 e41cfe48efe428eb6a6eaf218117f910d2083e79 SHA1 05f04ba44a384b7caf9e0490dd8e949035dbf5d6 SHA256 85d95ff9fda0dc0c2e4a106cefaf849f2409a1e57c04c3a9a046fedc25c5f390
 EBUILD vavoom-1.23.1.ebuild 6354 RMD160 53885dd794e49b01a2a779abb49b9d871df0c024 SHA1 2dbfe6f62fec7bafde3de68fd3835320fdffe4b5 SHA256 a5ef341a3e3f59859a655d37a291b55dd6c97cfd22c45b8238b4ca61ffddc358
-MISC ChangeLog 407 RMD160 46e8780c81f49e802752e9dd115eaa69685a8953 SHA1 fc8184b484c2d86a9120cbf2d8b72437adf1af7f SHA256 8750686870528b3479ab08606f9840a5b1890470b9b5c697cee901e53d2e0f0c
+EBUILD vavoom-9999.ebuild 6410 RMD160 cd77376b900c5857dafb90c5ff378e6349015ae4 SHA1 c0fa06e9e732ffe424db97e44d91f0e14a8a634b SHA256 0ee3edbd447f2e8104f0f3af6dbcb4b07e0968a4f0fac80b08895a17293e6e9c
+MISC ChangeLog 515 RMD160 f4e5ca17a04692a1de22bf9a49e1cda5105dc578 SHA1 8c7b18020606c65656bef1d8dd695fc30c8eaa55 SHA256 9f451c04e8319ff8368e32e37edea16b18334a7e4f264813ba493e9e1260784c
 MISC metadata.xml 303 RMD160 626272995441b20fd23b1d0a94603e98b97b0f1e SHA1 f3cae1ec3568e7717d7265a58d0b2e6d8efe88b5 SHA256 334d9b64af3b010a9fcdcbd8736eba2f81ff9d87dee3eb76b5adacb7d48afa37
diff --git a/games-fps/vavoom/vavoom-9999.ebuild b/games-fps/vavoom/vavoom-9999.ebuild
new file mode 100644
index 000000000..1ee1a8e0d
--- /dev/null
+++ b/games-fps/vavoom/vavoom-9999.ebuild
@@ -0,0 +1,240 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+inherit autotools eutils flag-o-matic subversion games
+
+DESCRIPTION="Advanced source port for Doom/Heretic/Hexen/Strife"
+HOMEPAGE="http://www.vavoom-engine.com/"
+ESVN_REPO_URI="https://svn.sourceforge.net/svnroot/vavoom/trunk/vavoom"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="allegro debug dedicated external-glbsp flac mad mikmod models music
+openal opengl sdl textures tools vorbis"
+
+QA_EXECSTACK="${GAMES_BINDIR:1}/${PN}"
+
+# From econf:  "Vavoom requires Allegro or SDL to compile"
+# SDL,like Allegro are *software* renderers in this game.
+# So, if not selected through proper USEs, the default is SDL,
+# without opengl (vavoom can run in software-mode only).
+# To enable it, enable proper USE.
+# OpenGL is the normally-desired hardware renderer, selected on command-line
+# (through "-opengl" switch). This switch is also added to the desktop entry,
+# if "opengl" USE flag is enabled
+
+SDLDEPEND=">=media-libs/libsdl-1.2
+	media-libs/sdl-mixer"
+ALLEGDEPEND=">=media-libs/allegro-4.0"
+OPENGLDEPEND="opengl? ( virtual/opengl )
+	sdl? ( ${SDLDEPEND} )
+	allegro? ( media-libs/allegrogl )
+	!sdl? ( !allegro? ( ${SDLDEPEND} ) )"
+DEPEND="media-libs/libpng
+	media-libs/jpeg
+	sdl? ( ${SDLDEPEND} )
+	!sdl? ( allegro? ( ${ALLEGDEPEND} ) )
+	!sdl? ( !allegro? ( !dedicated? ( ${OPENGLDEPEND} ) ) )
+	opengl? ( ${OPENGLDEPEND} )
+	vorbis? ( media-libs/libvorbis )
+	flac? ( media-libs/flac )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod )
+	openal? ( media-libs/openal )
+	external-glbsp? ( games-util/glbsp )"
+RDEPEND="${DEPEND}
+	allegro? ( media-sound/timidity++ )"
+PDEPEND="models? ( >=games-fps/vavoom-models-1.4 )
+	music? ( games-fps/vavoom-music )
+	textures? ( games-fps/vavoom-textures )"
+
+dir=${GAMES_DATADIR}/${PN}
+
+pkg_setup() {
+	local backend="media-libs/libsdl"
+
+	if ! use sdl && use allegro ; then
+		backend="media-libs/allegro"
+	fi
+
+	games_pkg_setup
+
+	# Do some important check ...
+
+	if use sdl && use allegro ; then
+		echo
+		ewarn "Both 'allegro' and 'sdl' USE flags enabled"
+		ewarn "Set default to SDL"
+	elif ! use sdl && ! use allegro ; then
+		ewarn "Both 'sdl' and 'allegro' USE flags disabled"
+		ewarn "Set default to SDL"
+	fi
+
+	# Base graphic/sound/music support is enabled?
+
+	echo
+	einfo "Doing some sanity check..."
+
+	# Graphic check
+	if ! built_with_use ${backend} X ; then
+		echo
+		eerror "Software Graphic support is not configured properly!"
+		eerror "Please rebuild ${backend} with 'X' USE flag enabled"
+		die "graphic support error"
+	fi
+
+	# Sound check
+	if ! built_with_use ${backend} alsa ; then
+		echo
+		eerror "Sound support is not configured properly!"
+		eerror "Please rebuild ${backend} with 'alsa' USE flag enabled"
+		die "sound support error"
+	fi
+
+	# Music check
+	if ! use allegro && ! built_with_use media-libs/sdl-mixer timidity ; then
+		echo
+		eerror "MIDI Music support is not configured properly!"
+		eerror "Please rebuild sdl-mixer with USE 'timidity' enabled!"
+		die "music support error"
+	fi
+
+	# OpenGL check
+	if use opengl ; then
+		if [ "${backend}" == "media-libs/libsdl" ] && ! built_with_use ${backend} opengl ; then
+			echo
+			eerror "OpenGL support is not configured properly!"
+			eerror "Please rebuild ${backend} with 'opengl' USE flag enabled"
+			die "opengl support error"
+		fi
+	else
+		echo
+		ewarn "'opengl' USE flag disabled. OpenGL is recommended, for best graphics."
+	fi
+
+	# Does user want external music? Vorbis support is needed
+	if use music && ! use vorbis ; then
+		echo
+		eerror "Ogg/Vorbis support is required for external music playing"
+		eerror "Please enable 'vorbis' USE flag for this package"
+		die "external music support error"
+	fi
+
+	echo
+	einfo "All is OK, let's build!"
+}
+
+src_unpack() {
+	subversion_src_unpack
+	cd "${S}"
+
+	./autogen.sh
+
+	# Set shared directory
+	sed -i \
+		-e "s:fl_basedir = \".\":fl_basedir = \"${dir}\":" \
+		source/files.cpp || die "sed files.cpp failed"
+
+	eautoreconf
+
+	# Set executable filenames
+	for m in $(find . -type f -name Makefile.in) ; do
+		sed -i \
+			-e "s:MAIN_EXE = @MAIN_EXE@:MAIN_EXE=${PN}:" \
+			-e "s:SERVER_EXE = @SERVER_EXE@:SERVER_EXE=${PN}-ded:" \
+			"${m}" || die "sed ${m} failed"
+	done
+}
+
+src_compile() {
+	local \
+		allegro="--without-allegro" \
+		sdl="--without-sdl"
+
+	# Sdl is the default, unless sdl=off & allegro=on
+	if ! use sdl && use allegro ; then
+		allegro="--with-allegro"
+	else
+		sdl="--with-sdl"
+	fi
+
+	use debug && append-flags -g2
+
+	egamesconf \
+		--enable-client \
+		${sdl} \
+		${allegro} \
+		$(use_with opengl) \
+		$(use_with openal) \
+		$(use_with external-glbsp) \
+		$(use_with vorbis) \
+		$(use_with mad libmad) \
+		$(use_with mikmod) \
+		$(use_with flac) \
+		$(use_enable dedicated server) \
+		$(use_enable debug) \
+		$(use_enable debug zone-debug) \
+		--with-iwaddir="${dir}" \
+		--disable-dependency-tracking \
+		|| die "egamesconf failed"
+
+	# Parallel compiling doesn't work for now :(
+	emake -j1 || die "emake failed"
+}
+
+src_install() {
+	local de_cmd="${PN}"
+
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	# Remove unneeded icon
+	rm -f "${D}/${dir}/${PN}.png"
+
+	doicon source/${PN}.png || die "doicon failed"
+
+	# Enable OpenGL in desktop entry, if relevant USE flag is enabled
+	use opengl && de_cmd="${PN} -opengl"
+	make_desktop_entry "${de_cmd}" "Vavoom"
+
+	dodoc docs/${PN}.txt || die "dodoc vavoom.txt failed"
+
+	if use tools; then
+		# The tools are always built
+		dobin utils/bin/{acc,fixmd2,vcc,vlumpy} || die "dobin utils failed"
+		dodoc utils/vcc/vcc.txt || die "dodoc vcc.txt failed"
+	fi
+
+	prepgamesdirs
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+
+	elog "Copy or link wad files into ${dir}"
+	elog "(the files must be readable by the 'games' group)."
+	elog
+	elog "Example setup:"
+	elog "ln -sn ${GAMES_DATADIR}/doom-data/doom.wad ${dir}/"
+	elog
+	elog "Example command-line:"
+	elog "   vavoom -doom -opengl"
+	elog
+	elog "See documentation for further details."
+
+	if use tools; then
+		echo
+		elog "You have also installed some Vavoom-related utilities"
+		elog "(useful for mod developing):"
+		elog
+		elog " - acc (ACS Script Compiler)"
+		elog " - fixmd2 (MD2 models utility)"
+		elog " - vcc (Vavoom C Compiler)"
+		elog " - vlumpy (Vavoom Lump utility)"
+		elog
+		elog "See the Vavoom Wiki at http://vavoom-engine.com/wiki/ or"
+		elog "Vavoom Forum at http://www.vavoom-engine.com/forums/"
+		elog "for further help."
+	fi
+}